How can one delete an element and it corresponding values from the array of arrays?

supriyoch_2008 has asked for the wisdom of the Perl Monks concerning the following question:

Hi PerlMonks,

I have 3 arrays i.e. @sample1, @sample2 and @sample3 each with 4 elements. One element in one array is linked to the corresponding position element in the other two arrays. I mean to say that a, 1 & x1 are linked and so are the others. Now I want to put all the arrays in a bigger array @big. At some point of time, I might be interested to delete one element x3 from @sample3 and its corresponding values from @sample1 and @sample2 i.e. c & 3 and likewise from array @big. The big array is an array of arrays. I am at my wit's end to find out the resultant big array and other three arrays after removing x3 & its corresponding values from @sample1 & @sample2. I am looking forward to suggestions and guidance from PerlMonks in this matter.

#!/usr/bin/perl
use warnings;  
use strict; 
 my @sample1=qw/a b c d/; 
 my @sample2=qw/1 2 3 4 /; 
 my @sample3=qw/x1 x2 x3 x4/; 
# Joined array: 
 my @big=(@sample1, @sample2, @sample3); 
print"\n Original Big Array:\n
@big\n";
# To store the array values in a hash:  
my %h;

# Code for removing x3 & its corresponding values from big array???
# and code for modified @sample1, @sample2 & @sample3 ???
$deleted_ele="x3"; 
 ???? 

print"\n Original big array: @big\n 
 Resultant big array: @mod_big\n 
 Deleted Element: $deleted_ele\n  
 Modified sample1: @mod_sam1\n   
          sample2: @mod_sam2\n 
          sample3: @mod_sam3\n\n";   

exit;
[download]

Result should look something like:

Original big array: a b c d 1 2 3 4 x1 x2 x3 x4 
Resultant big array: a b d 1 2 4 x1 x2 x4 
Deleted Element: x3  
Modified @sample1: a b d 
         @sample2: 1 2 4 
         @sample3: x1 x2 x4
[download]

Comment on How can one delete an element and it corresponding values from the array of arrays? Select or Download Code

Replies are listed 'Best First'.

Re: How can one delete an element and it corresponding values from the array of arrays?
by tobyink (Canon) on Mar 18, 2013 at 08:00 UTC

It has already been noted in your previous thread that a set of arrays is a poor choice of data structure for your task. Difficulty of deleting a record is one problem of many that you'll encounter - it's much easier using hashes.

#!/usr/bin/env perl     

use v5.12;
use Data::Dumper;

my %students = (
    x1 => {
        name       => "Alice",
        telephone  => 1001,
        regno      => "x1",
    },
    x2 => {
        name       => "Bob",
        telephone  => 1002,
        regno      => "x2",
    },
    x3 => {
        name       => "Carol",
        telephone  => 1003,
        regno      => "x3",
    },
);

say "Let's look at the data structure...";
print Dumper \%students;

say "What is student x1's telephone number?";
say $students{x1}{telephone};

say "What is Carol's telephone number?";
my ($carol) = grep { $_->{name} eq "Carol" } values %students;
say $carol->{telephone};

say "Now let's delete student x2...";
delete $students{x2};

say "And change Carol's phone number";
$carol->{telephone} = "1004";

say "Let's look at the data structure again...";
print Dumper \%students;
[download]

package Cow { use Moo; has name => (is => 'lazy', default => sub { 'Mooington' }) } say Cow->new->name