Re^2: Creating a unique variable type

[Athanasius]

Perl is not a “strongly typed” language.

True for some definitions of “strongly typed“ (see Strong_typing), but in this context I think it’s clearer if we describe Perl as dynamically typed, in contrast to languages like C which are statically typed. With static typing, a variable’s type is known at compile time; with dynamic typing, a (scalar) variable’s data type is determined at runtime, and may change as the script executes — $foo may hold a string, then an integer, then a reference, ...

You cannot now say my $foo : integer;

Well, not in core Perl, no. But if you have objects, you’ll probably be using an object system (and if not, please see the picture on Your Mother’s home page!), and in an object system like Moose you can certainly specify that $foo is an Int. Here is one way to approach the OP’s task using Moose:

#! perl
use strict;
use warnings;
use Data::Dump;

package Square
{
    use Moose;
    use namespace::autoclean;

    has queen_is_present =>
    (
        is      => 'rw',
        isa     => 'Bool',
        default =>  0,
    );

    has is_threatened =>
    (
        is      => 'rw',
        isa     => 'Int',
        default =>  0,
    );

    no Moose;
    __PACKAGE__->meta->make_immutable;
}

use enum qw(
               :Rank_=0 r1 r2 r3 r4 r5 r6 r7 r8
               :File_=0  a  b  c  d  e  f  g  h
           );

my @board;

for my $rank (Rank_r1 .. Rank_r8)
{
    $board[$rank][$_] = Square->new() for File_a .. File_h;
}

$board[1][2]->is_threatened(7);        # OK:            7   is     an 
+'Int'
dd @board;
$board[3][4]->is_threatened('foo');    # Runtime error: foo is not an 
+'Int'

But this is still dynamic typing: if a type mismatch occurs, it is a runtime error which results.

Hope that helps,

[sundialsvc4]

There is, indeed, not a single phrase in programming vernacular that has but one unambiguous meaning ... except maybe “crash.”