Re: removing lines that are in the end of a file

[BrowserUk]

The answers so far do not seem to have noticed the first line which also contains "SIL".

This is pretty trivial using File::ReadBackwards:

#! perl -slw
use strict;
use File::ReadBackwards;

my $file = $ARGV[ 0 ];

tie *BW, 'File::ReadBackwards', $file;

my $lastpos = -s( $file );
while( <BW> ) {
    last unless /SIL/;
    $lastpos = tell( BW )
}
truncate $file, $lastpos;
close BW;

A sample run:

<Reveal this spoiler or all in this thread>

[bhargavkanakiya]

Thanks a lot to you. This also removes the last line with SIL. This is not how i wanted but still you have made my task a lot easier. I can add last SIL using other software that i am currently working on.

[BrowserUk]

This also removes the last line with SIL. This is not how i wanted

ReadBackwards() has to do strange things with tell, so a little extra work is involved. Try this version:

#! perl -slw
use strict;
use File::ReadBackwards;

my $file = $ARGV[ 0 ];

tie *BW, 'File::ReadBackwards', $file;

my $lastpos = -s( $file );
my $len = 0;
while( <BW> ) {
    $len = length() +1;
    next unless length >1;
    last unless /SIL/;
    $lastpos = tell( BW );
}
truncate $file, $lastpos + $len;
close BW;

Note: You won't need the +1 in the  $len = length() +1; line if you are not on Windows.