split at '- - -'

[Saved]

A log file has records separated by a lines with only 3 minus signs. I wish to split on them, but it is not working. I have tried many combinations of \--- \-\-\- with single & double quotes or none. My preference it to enter the Record separator as a command line parameter, but I could hard-code it if need be. Any help in this matter would be much appreciated. Thanx.

[blue_cowdawg]

Since I wasn't 100% sure of what you were asking for, I give you two! two solutions in one!

#!/usr/bin/perl -w 
use strict;
use Data::Dumper;
my $line="this---is---Sparta!";

#
# Case 1 a line with *fields* seperated by dashes
my @f=split('---',$line);  #split the line along the dashes

print Dumper(\@f);

# Case 2   Records seperated by three dashes
my $oldIFS=$/; #save the old IFS

$/ = undef;    # make it undefined
$line=<DATA>;  # slurp in file
$/=$oldIFS;    # restore IFS

@f = split('---',$line); # split on dashes
$_ =~ s/^\n// foreach @f; # remove leading EOL
chomp (@f); # remove traiing EOL

print Dumper(\@f);


exit(0);   # we're done, going home
__END__
line1
---
line2
---
line3

when run gives you:

$VAR1 = [
          'this',
          'is',
          'Sparta!'
        ];
$VAR1 = [
          'line1',
          'line2',
          'line3'
        ];

[tobyink]

undef isn't the only useful thing you can assign to $/...

use strict;
use Data::Dumper;

my @f;
{
    local $/ = "\n---\n";
    chomp(@f = <DATA>);
}

print Dumper(\@f);
exit;

__END__
line1
---
line2
---
line3
---

[hdb]

As a small variant, there could also be a hybrid case where you want to split on "---" if they are on a line by themselves but not if they occur within a line. Adapting Peter's code:

#!/usr/bin/perl -w 
use strict;
use Data::Dumper;

my $line;
{
        local $/ = undef; 
        $line=<DATA>; 
}
chomp $line;
my @f = split('\n---\n',$line);
print Dumper(\@f);

__END__
line1
---
line2---line2a
---
line3

[Saved]

Thanx, looking good...