Re: array => hash of occurrence indexes

[kcott]

G'day pldanutz,

I generally think it's better to pass around scalars than entire data structures, so returning a reference to that hash would be my preference.

If you wrapped $h{$k} in @{...}, you could dispense with if (! $h {$k}) { $h {$k} = [] } entirely.

Even if you're using 5.012 for other reasons elsewhere in your code, I see little, if any, value in using each here. It's easy to write it for any Perl5.

Putting all that together, you could code occurrences() like this instead:

sub occurences {                                                    
    my %h;          
    my $i = 0;
    push @{$h{$_}}, $i++ for @_;
    return \%h;
}

If you were looking for a golf answer, you could start with the following and then proceed to remove whitespace until illegibility was achieved. :-)

sub occurences { my ($i, %h) = 0; push @{$h{$_}}, $i++ for @_; \%h }

Here's my tests:

$ perl -Mstrict -Mwarnings -e '
    use Data::Dumper;

    sub occurences {                                                  
+  
        my %h;          
        my $i = 0;
        push @{$h{$_}}, $i++ for @_;
        return \%h;
    }
                                               
    my $h = occurences(2, 1, 3, 4, 3, 4, 4, 5);
    print Dumper $h;
'
$VAR1 = {
          '1' => [
                   1
                 ],
          '3' => [
                   2,
                   4
                 ],
          '2' => [
                   0
                 ],
          '4' => [
                   3,
                   5,
                   6
                 ],
          '5' => [
                   7
                 ]
        };

$ perl -Mstrict -Mwarnings -e '
    use Data::Dumper;

    sub occurences { my ($i, %h) = 0; push @{$h{$_}}, $i++ for @_; \%h
+ }
              
    my $h = occurences(2, 1, 3, 4, 3, 4, 4, 5);
    print Dumper $h;
'
$VAR1 = {
          '4' => [
                   3,
                   5,
                   6
                 ],
          '1' => [
                   1
                 ],
          '5' => [
                   7
                 ],
          '2' => [
                   0
                 ],
          '3' => [
                   2,
                   4
                 ]
        };