Re: Warning while using ternary operator

[Anonymous Monk]

The ternary operator is not a shorthand way of writing an if block. It's a shorthand way of writing an if block that returns a value.

if ($expression) {
  $var = "foo";
} else {
  $var = "bar";
}

# WRONG
$expression ? $var = "foo" : $var = "bar";

# correct
$var = $expression ? "foo" : "bar";

[kcott]

This is bad information.

The expression

$expression ? $var = "foo" : $var = "bar";

is only "# WRONG" because of operator precedence (see perlop: Operator Precedence and Associativity). Here's how it is parsed:

$ perl -MO=Deparse,-p -e '$expression ? $var = "foo" : $var = "bar";'
(($expression ? ($var = 'foo') : $var) = 'bar');
-e syntax OK

This is explained in perlop: Conditional Operator. Correcting the precedence with parentheses:

$ perl -MO=Deparse,-p -e '$expression ? ($var = "foo") : ($var = "bar"
+);'
($expression ? ($var = 'foo') : ($var = 'bar'));
-e syntax OK

I do not dispute that '$var = $expression ? "foo" : "bar";' is a better way to write '$expression ? ($var = "foo") : ($var = "bar");'. In fact, the documentation also recommends this.

Once corrected as indicated, here's how your "# WRONG" code behaves:

#!/usr/bin/env perl -l

use strict;
use warnings;

for my $expression (0, 1) {
    my $var = '';
    $expression ? ($var = 'foo') : ($var = 'bar');
    print "\$expression = '$expression'; \$var = '$var'";
}

Output:

$expression = '0'; $var = 'bar'
$expression = '1'; $var = 'foo'

[AnomalousMonk]

But what does the syntactically correct statement
    $expression ? $var = "foo" : $var = "bar";
actually do?

>perl -wMstrict -le
"for my $expression (0, 1) {
   my $var = '';
   $expression ? $var = 'foo' : $var = 'bar';
   print qq{if \$expression is $expression, \$var is '$var'}
   }
"
if $expression is 0, $var is 'bar'
if $expression is 1, $var is 'bar'

It seems the statement is just an expensive equivalent to the statement
    $var = 'bar';
The reason why is left as a exercise for simonz (after the recommended perusal of perlop :)