good chemistry is complicated,and a little bit messy -LW PerlMonks

### Re^6: Comparing two arrays

by roboticus (Chancellor)
 on Dec 16, 2013 at 21:19 UTC ( #1067367=note: print w/replies, xml ) Need Help??

in reply to Re^5: Comparing two arrays

I've had to add and edit a bit of code outside the actual compared routines. The OP mentioned that the ratio of 1 to 0 entries is 1::500, which is a fact I used to come up with my approach. So the first change is the ability to set the probability of 1 bits.

Since the 1 bits are sparse, rather than making an explicit vector, I use a list of the positions of the 1 bits. In order to come up with the same results, I converted the Y vectors list format.

The biggest change outside of the comparison routine is the setup routine that transforms the xArray. The concept was to do something like this: Build an artificial set of vectors each with 1 bit--one vector per bit position. Then we compare each of these artificial vectors against the xArray set, resulting in a list of x vectors for each bit position. Then in our comparison, we aggregate the selected bins. Thus, if y has five bits in it, we add in the five partial products from the eigenset vectors. So the process of building the lists is amortized over the run of comparisons.

Having said all that, here it is. As mentioned previously, I came up with my approach when I saw that the distribution of 1s was very sparse. As the density of 1s increases, the routine gets progressively slower.

```\$ perl 1067357_mcm.pl -I=1 -N=100 -W=4000 -P=.05
<<< snipped >>>
Rate   array strings    bits    robo
array   2.33e-02/s      --    -98%    -99%   -100%
strings     1.45/s   6122%      --    -25%    -72%
bits        1.92/s   8156%     33%      --    -63%
robo        5.26/s  22495%    263%    174%      --

\$ perl 1067357_mcm.pl -I=1 -N=100 -W=4000 -P=.5
<<< snipped >>>
s/iter   array    robo strings    bits
array     60.4      --    -87%    -99%    -99%
robo      7.75    680%      --    -91%    -93%
strings  0.690   8659%   1023%      --    -23%
bits     0.530  11304%   1362%     30%      --
```#! perl -slw
use strict;
use Benchmark qw[ cmpthese ];
use Data::Dump qw[ pp ]; \$Data::Dump::WIDTH = 500;

our \$I //= -1;
our \$N //= 1000;
our \$W //= 15_000;

# OP mentions that 1 bits are sparse (1 :: 500)  It doesn't make a dif
+ference for straight
# bit comparison techniques, but it *does* for mine.
our \$P //= 0.002;
our @xArrays = map[ map { rand()<\$P ? 1 : 0 }  1 .. \$W ], 1 .. \$N;
our @yArrays = map[ map { rand()<\$P ? 1 : 0 }  1 .. \$W ], 1 .. \$N;

our @xStrings = map{ join '', @\$_  } @xArrays;
our @yStrings = map{ join '', @\$_  } @yArrays;

our @xBits = map{ pack 'b*', \$_ } @xStrings;
our @yBits = map{ pack 'b*', \$_ } @yStrings;

# Because the bit vectors are sparse, I'm storing them as lists of bit
+ positions, rather
# than bit vectors, so I'm converting Y
my \$start = time;
our @yArrays2;
for my \$y (0 .. \$#yArrays) {
for my \$bitcol (0 .. \$W-1) {
push @{\$yArrays2[\$y]}, \$bitcol if \$yArrays[\$y][\$bitcol];
}
}
my \$cur = time - \$start;
print "Converting yArrays format took \$cur sec.\n";

# I bin the X arrays after which I never use them again, so I'll bin t
+hem directly from the
# originally generated vectors.
\$start = time;
our @bitcols;
for my \$x (0 .. \$#xArrays) {
for my \$bitcol (0 .. 14_999) {
push @{\$bitcols[\$bitcol]}, \$x if \$xArrays[\$x][\$bitcol];
}
}
\$cur = time - \$start;
print "Binning xArrays took \$cur sec.\n";

cmpthese \$I, {
array => q[
my %top10s;
for my \$x ( 0 .. \$#xArrays ) {
for my \$y ( 0 .. \$#yArrays ) {
my \$count = 0;
\$xArrays[\$x][\$_] == 1 && \$yArrays[\$y][\$_] == 1 and ++\$
+count for 0 .. \$#{ \$xArrays[ 0 ] };
\$top10s{"\$x:\$y"} = \$count;
my \$discard = ( sort{ \$top10s{\$a} <=> \$top10s{\$b}  ||
+\$a cmp \$b} keys %top10s )[ 0 ];
keys( %top10s ) > 10 and delete \$top10s{\$discard};
}
}
\$I == 1 and pp ' arrays: ', %top10s;
],
strings => q[
my %top10s;
for my \$x ( 0 .. \$#xStrings ) {
for my \$y ( 0 .. \$#yStrings ) {
my \$count = ( \$xStrings[\$x] & \$yStrings[\$y] ) =~ tr[1]
+[];
\$top10s{"\$x:\$y"} = \$count;
my \$discard = ( sort{ \$top10s{\$a} <=> \$top10s{\$b}  ||
+\$a cmp \$b} keys %top10s  )[ 0 ];
keys( %top10s ) > 10 and delete \$top10s{\$discard};
}
}
\$I == 1 and pp 'strings: ', %top10s;
],
bits => q[
my %top10s;
for my \$x ( 0 .. \$#xBits ) {
for my \$y ( 0 .. \$#yBits ) {
my \$count = unpack '%32b*', ( \$xBits[\$x] & \$yBits[\$y]
+);
\$top10s{"\$x:\$y"} = \$count;
my \$discard = ( sort{ \$top10s{\$a} <=> \$top10s{\$b}  ||
+\$a cmp \$b} keys %top10s )[ 0 ];
keys( %top10s ) > 10 and delete \$top10s{\$discard};
}
}
\$I == 1 and pp '   bits: ', %top10s;
],
robo => sub {
my %top10s;
my \$cur_min=0;
for my \$y ( 0 .. \$#yArrays2 ) {
my %x;
for my \$bitcol (@{\$yArrays2[\$y]}) {
\$x{\$_}++ for @{\$bitcols[\$bitcol]};
}
for my \$k (keys %x) {
next unless \$x{\$k} >= \$cur_min;
\$top10s{"\$k:\$y"} = \$x{\$k};
my \$discard = ( sort{ \$top10s{\$a} <=> \$top10s{\$b} || \$
+a cmp \$b } keys %top10s )[ 0 ];
if (keys %top10s > 10) {
}
}
}
\$I == 1 and pp '   bits: ', %top10s;
},
};

...roboticus

When your only tool is a hammer, all problems look like your thumb.

Replies are listed 'Best First'.
Re^7: Comparing two arrays
by BrowserUk (Pope) on Dec 16, 2013 at 22:59 UTC
I came up with my approach when I saw that the distribution of 1s was very sparse. As the density of 1s increases, the routine gets progressively slower.

None the less, the challenge is met and I stand corrected.

With the rise and rise of 'Social' network sites: 'Computers are making people easier to use everyday'
Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
"Science is about questioning the status quo. Questioning authority".
In the absence of evidence, opinion is indistinguishable from prejudice.

Create A New User
Node Status?
node history
Node Type: note [id://1067367]
help
Chatterbox?
and all is quiet...

How do I use this? | Other CB clients
Other Users?
Others scrutinizing the Monastery: (4)
As of 2018-05-26 06:31 GMT
Sections?
Information?
Find Nodes?
Leftovers?
Voting Booth?
World peace can best be achieved by:

Results (192 votes). Check out past polls.

Notices?