hashes in the Nth dimension

[perlaintdead]

I'm look for a way to retrieve a value where the depth might vary.
like: func("first second last");
At first i tried a loop involving this general idea:

%meows = {
  kittehs => {
    purr => "happy",
    hiss => "mad",
    weather => {
      tailflic => "rain",
      shaking => "a doosy",
    },
  },
}

$tail = $meows{"kittehs"};
$tail = $tail{"weather"};
$tail = $tail{"tailflic"};

but this method of "unraveling" the hash doesn't work and i can't just have a fixed amount of currlies because the depth isn't known.

[wazat]

I'm not sure if I understand your question.

Your general idea isn't syntactically correct. Is this what you mean?

use strict; 
use warnings; 

my %meows = (
  kittehs => {
    purr => "happy",
    hiss => "mad",
    weather => {
      tailflic => "rain",
      shaking => "a doosy",
    },
  },
)

sub func {
    my $h_ref = shift;
    my $cur = $h_ref;
    for my $k (@_)
    {
        $cur = $cur->{$k}
    }
    return $cur;
}

print  $meows{"kittehs"}->{weather}->{tailflic}, "\n";

print func( \%meows, "kittehs", "weather", "tailflic"), "\n";
__END__
rain
rain

[perlaintdead]

my example wasn't the code i was trying to use but yeah basically what i was shooting for

[perlaintdead]

thanks

[roboticus]

perlaintdead:

There are multiple approaches you could take, but to choose one, you'd have to know how you want to access your data. If you have a varying list of keys, for example, you could make a subroutine that would unravel the hashes:

my @keys = qw( kittehs weather tailflic );
my $value = unravel_hash(\%meows, @keys );

sub unravel_keys {
    my $ref = shift;
    while (@_) {
        my $key = shift;
        return undef if ! exists $ref->{$key};
        $ref = $ref->{$key};
    }
    # Ran out of keys, so $ref is the requested value
    return $ref;
}

Of course, if you have array references mixed in, you'll have to make more complex code to check whether to reference by hash key or array index.

However, the module Data::Diver already does this for you, so you could just download and install it!

...roboticus

When your only tool is a hammer, all problems look like your thumb.

[Athanasius]

Here is another approach using the Hash::Flatten module:

#! perl
use strict;
use warnings;
use Hash::Flatten 'flatten';

my %meows =
(
    kittehs =>
    {
        purr    => 'happy',
        hiss    => 'mad',
        weather =>
        {
            tailflic => 'rain',
            shaking  => 'a doosy',
        },
    },
);

my $flat_meows = flatten(\%meows);
my @keys       = qw(kittehs weather tailflic);
my $new_key    = join '.', @keys;

printf "\$meows{%s} = %s\n", $new_key, $flat_meows->{$new_key};

Output:

18:26 >perl 831_SoPW.pl
$meows{kittehs.weather.tailflic} = rain

18:26 >

Hope that helps,