Re: Importing variables (not functions) from in-file packages

[tobyink]

The beauty of our is that there is no need to export within the same file. It works lexically.

use strict;
use warnings;

package MyPackage; # temporarily step into MyPackage
our $globalVar;
package main;      # back to main

$globalVar = 42;

print $MyPackage::globalVar, "\n";

[puterboy]

Ahhh interesting. I didn't know that one could step in & out of a package multiple times. Thanks

[tobyink]

Yup - and you don't even need to do so at the "top level". package statements can appear within blocks. Like...

package main;
use strict;
use warnings;

{
  package Person;
  
  use Data::Dumper ();   # load, but import nothing!
  
  sub new {
    my $class = shift;
    bless {@_}, $class;
  }
  
  sub dump {
    my $self = shift;
  
    package Data::Dumper;
  
    # The following line is executed in Data::Dumper,
    # so it can see the "Dumper" sub defined there!
  
    print Dumper($self);
  }

  # We're back to the Person package here because
  # the closing brace ended the Data::Dumper package
  printf "Line %d is in package %s\n", __LINE__, __PACKAGE__;
}

# And now we're back to the main package.
printf "Line %d is in package %s\n", __LINE__, __PACKAGE__;

my $bob = Person->new(name => 'Robert');
$bob->dump;