extract month and year from localtime

[oikool]

how to extract month and year from localtime? in perl

$stimm = localtime($^T);

print ((split/ /,$stimm)[1]);

[davido]

My favorite quote from the Inline::C-Cookbook: "A concept is valid in Perl only if it can be shown to work in one line."

$ perl -E 'say join( ", ", sub{ 1+shift, 1900+shift }->((localtime tim
+e)[4,5]) );'

This calls localtime(time) in list context, and takes a slice of the list consisting of elements #4 and #5, which are month and year. The month is zero-based, so we have to add 1. The year is 1900 based, so we have to add 1900. We do this by passing the two values into an anonymous sub that exists only for the purpose of applying some math to its inputs. We immediately dereference the sub (ie, invoke it) and return the results (still in list context). Then join the results (2 and 2014) with a comma, and print them.

Inline::C has nothing to do with the solution, of course, but somehow the quote seems appropriate. ;)

[hdb]

This kind of construct

    sub{ 1+shift, 1900+shift }->((localtime time)[4,5])

I have been missing for a long time. Many many thanks!

[davido]

Yeah, I was kind of glad I remembered it. It seems too often we end up creating some temporary variables to receive and decorate values, when we can do our decorating inline with an immediate-use anonymous sub.

[hdb]

If you use localtime in list context (for example by assigning it to an array or a list), you get all parts separately. For example it says in the documentation:

($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time
+);

[kcott]

G'day oikool,

You can use the built-in module Time::Piece for this task. Check the documentation for different representations of year (e.g. 2-digit or 4-digit) and month (e.g. number: starting at 0 or 1; or name: full or abbreviated). Here's the basic code:

#!/usr/bin/env perl -l

use strict;
use warnings;

use Time::Piece;

my $t = localtime($^T);

print 'Month: ', $t->month;
print 'Year:  ', $t->year;

Output:

Month: Feb
Year:  2014

[atcroft]

From perldoc -f localtime,

#  0    1    2     3     4    5     6     7     8
($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = 
localtime(time);

and

$mday is the day of the month and $mon the month in the range 0..11, with 0 indicating January and 11 indicating December. This makes it easy to get a month name from a list:

  my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  print "$abbr[$mon] $mday";
  # $mon=9, $mday=18 gives "Oct 18"

$year contains the number of years since 1900. To get a 4-digit year write:

  $year += 1900;

Given this, then:

# 2014-02
perl -le 'my (@ym) = (localtime($^T))[5,4]; $ym[0] += 1900; 
$ym[1]++; print sprintf qq{%4d-%02d}, @ym;'

or

# 2014-Feb
perl -le 'my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep 
Oct Nov Dec); my (@ym) = (localtime)[5,4]; 
$ym[0]+= 1900; print sprintf qq{%4d-%3s}, $ym[0], $abbr[$ym[1]];'

Hope that helps.

[Anonymous Monk]

use POSIX();
my @lt = localtime ;
my $year  = POSIX::strftime( '%Y', @lt );
my $month = POSIX::strftime( '%m', @lt );

See Re: error on file open, Re^2: Date plus Time sort from file ( Time::Piece->strptime/strftime example, Re: Subtracting minutes from a string ( Time::Piece->strptime )