Question on REGEXP

[Anonymous Monk]

Dear Monks,
I wanted to ask a question regarding pattern matching. My problem is that I seem to be unable to match special characters, like | for example.
So, in my script that I am trying to match some IDS, like 1QJ8:A|PDBID|CHAIN, if I try to say:

$id_to_match="1QJ8:A|PDBID|CHAIN";

while(<>)
{
 if($_=~/$id_to_match/)
}

I get no matches (the ID exists though). Do I need to put something in the regexp?
Thank you!

[choroba]

| has a special meaning in a regex: it separates alternatives. If you know your variable should not contain any special characters, you can "quote" it by using \Q:

my $id_to_match = '1QJ8:A|PDBID|CHAIN';
while (<>) {
    if (/\Q$id_to_match/) {
        # ...
    }
}

See Escape sequences in perlre for details.

[Anonymous Monk]

So this escapes everything, right? I mean, if you want to treat any given character as normal character, without any exceptions/special meanings.

[choroba]

Yes. If you only want to escape some characters, you can try the hard way: adding \ in front of them in the string. If you want to escape anything in a substring, you can end the effect of \Q by \E.

/\Q$literal_characters\E$special_characters/

[AnomalousMonk]

I get no matches (the ID exists though).

Others have addressed the basic problem, but the statement quoted from the OP suggests something else is going on that may merit another look at the actual code (Update: and/or data).

The example below shows that a match should have occurred even without metaquoting if the string being matched against contained the 'id' string as a substring; however, the actual matched sequence would not be as expected due to regex alternation operators embedded in the 'id' string.

c:\@Work\Perl>perl -wMstrict -le
"my $id  =    '1QJ8:A|PDBID|CHAIN';
 my $str = 'xxx1QJ8:A|PDBID|CHAINxxx';
 ;;
 print qq{matched '$&'} if $str =~ /$id/;
"
matched '1QJ8:A'

BTW: All the usual cautions against the use of  $& in production code apply — and a cooty-shot too!

[7stud]

My preferred way to escape a special regex character, e.g the alternation(|) character, is to use a character class:

use strict;
use warnings;
use 5.014;  

my $pattern =<<'END_OF_PATTERN';
    1QJ8:A    #These characters, followed by...
    [|]       #a literal pipe, followed by...
    PDBID     #these characters, folllowed by...
    [|]       #a literal pipe, followed by...
    CHAIN     #this word
END_OF_PATTERN

my $str = '1QJ8:A...PDBID....CHAIN...1QJ8:A|PDBID|CHAIN';
my @matches =  $str =~ /$pattern/gxms;

say "@matches";

--output:--
1QJ8:A|PDBID|CHAIN