Grabbing XML from PerlMonks

[patgas]

I was putting together a little code to grab the XML from User Nodes Info XML Generator, and I only seem to be getting a newline back from that node. I've tried substituting Newest Nodes XML Generator, which works, and Node Query XML Generator, which doesn't. I'm completely stumped. Can anyone offer me a little advice?

#!/usr/bin/perl -w

use strict;
use HTTP::Cookies;
use LWP::UserAgent;
use URI::URL;

my $user = 'USER_NAME_HERE';
my $password = 'PASSWORD_HERE';

my $agent = new LWP::UserAgent();

my $cookie = new HTTP::Cookies(
                 file     => 'cookies.dat',
                 autosave => 1
             );

$agent->cookie_jar( $cookie );

my $url = new URI::URL 'http://perlmonks.org/index.pl';

$url->query_form(
          op          => 'login',
          node_id     => '109',
          lastnode_id => '131',
          user        => $user,
          passwd      => $password
      );

my $request = new HTTP::Request 'GET', $url->as_string();
my $result = $agent->request( $request );

die "Error logging in: $result->code $result->message"
    if ( !$result->is_success );

$url = new URI::URL 'http://perlmonks.org/index.pl';

$url->query_form( node => "User Nodes Info XML Generator" );

$request = new HTTP::Request 'GET', $url->as_string();
$result = $agent->request( $request );

die "Error receiving results: $result->code $result->message"
    if ( !$result->is_success );

print '->', $result->content, '<-';

"We're experiencing some Godzilla-related turbulence..."

[chromatic]

LWP::UserAgent doesn't appear to set a cookie without a FQDN. Unfortunately, perlmonks.org isn't fully qualified. Use www.perlmonks.org or perlmonks.org. with the trailing dot. (If you look at HTTP::Cookies::add_cookie_header(), you'll see that it expects there to be two dots in the domain name.)

Adding the trailing dot fixed it on my machine.

[patgas]

I had gotten as far as realizing that the cookie wasn't being set, and I had started looking at HTTP::Cookies before I left work, but I didn't catch this. That fixed it perfectly, thanks!

"We're experiencing some Godzilla-related turbulence..."