keeping split deliimiters causing empty string elements

[previous]

How can improve the regex to remove the double commas seen. Thank you in anticipation.

my $eqn='$profit=$sales-$cogs';
my @wrds = split /(=)|(-)/, $eqn;  
#gives profit,=,,$sales,,-,$cogs
my $wrds_str=join(",",@wrds);
$wrds_str =~ s/,,/,/g;
@wrds = split /,/, $wrds_str; 
print join ",",@wrds;

[Athanasius]

Hello previous,

TMTOWTDI: Put the separator in a single capture group:

use strict;
use warnings;
use Data::Dump;

my  $eqn  = '$profit=$sales-$cogs';
my  @wrds =  split /(=|-)/, $eqn;
dd \@wrds;

Output:

23:13 >perl 1596_SoPW.pl
["\$profit", "=", "\$sales", "-", "\$cogs"]

23:13 >

See the final paragraph of split.

Hope that helps,

[previous]

Hello Athanasius Thanks very much for your help and solution.

[BrowserUk]

print join ',', split '([=-])', '$profit=$sales-$cogs';;
$profit,=,$sales,-,$cogs

[previous]

That's great thank's very much for your help and solution.

[AnomalousMonk]

As BrowserUk and Athanasius have both shown, the best way to deal with the problem (in split and in regex matching in general) is not to have unmatched capture groups, which return undef, in the first place.

Sometimes, you're just gonna have capture groups that don't and won't match. The Perl version 5.10 Extended Patterns  (?|pattern) "branch reset" operator is very handy for this:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $eqn = '$profit=$sales-$cogs';
 my @wrds = split /(?|(=)|(-))/, $eqn;
 dd \@wrds;
"
["\$profit", "=", "\$sales", "-", "\$cogs"]

If you don't have access to 5.10 or in general need to remove undefined (or zero-length, or whatever...) elements from a list, there's always grep:

c:\@Work\Perl\monks>perl -wMstrict -MData::Dump -le
"my $eqn = '$profit=$sales-$cogs';
 my @wrds = grep defined, split /(=)|(-)/, $eqn;
 dd \@wrds;
"
["\$profit", "=", "\$sales", "-", "\$cogs"]

Update: Revised wording; meaning unchanged.

[previous]

Thank you very much indeed for the pointers...for further reading. That's extremely helpful.