Why my Regex doesn't work

[flappygoat]

Hi everyone. I want to have a regex that matches all occurrences of a letter sandwiched between 2 same letters(the letter in the middle is different than the two outer letters) and changes the middle letter so that all 3 letters are the same. For instance it would change CCHHHCHHCHC into CCHHHHHHHCC. I only work with 3 chars C,H,E but I wrote for a general case, but it won't work the way I want. my regex is

s/(\w)[^\1]\1/$1$1$1/gi

I don't understand why it matches HHH if I wrote that the middle letter cannot be the same as first. Why is this wrong and how to make it work?

[AnomalousMonk]

A \n regex backreference is not active in a character class;  [^\1] is equivalent to  [^1]   (Update: Nope. Not quite. See Update below.)

Try:

c:\@Work\Perl\monks>perl -wMstrict -le
"my $s = 'CCHHHCHHCHC';
 print qq{'$s'};
 ;;
 $s =~ s/(\w) (?!\1). \1/$1$1$1/xgi;
 print qq{'$s'};
"
'CCHHHCHHCHC'
'CCHHHHHHHHC'

(note the use of the  /x modifier — for clarity only).

Update: In fact,  \1 in a character class is an octal escape sequence:

c:\@Work\Perl\monks\flappygoat>perl -wMstrict -le
"my $s = qq{\1\x01\o{001}\cA};
 print 'match' if $s =~ /[^\1]/;
 print 'count: ', $s =~ tr/\1//;
"
count: 4

(no match; nothing printed). Wonderful what you can find out if you actually test stuff.

[Anonymous Monk]

The OP wanted CCHHHHHHHCC, not CCHHHHHHHHC. Maybe that's a typo, or maybe he wants all the surrounded characters substituted simultaneously, as in a cellular automaton. In that case,

s/(?<=(\w))(?!\1).(?=\1)/$1/g;

[Not_a_Number]

Yeah. The problem seems underspecified.

For example, what output would the OP want from CHCHC?

AnomalousMonk's snippet outputs CCCHC, while anonymonk's gives CCHCC...

[flappygoat]

thank you so much! That is exactly what I needed. I wonder tho if it's possible to do without "lookaround".

[flappygoat]

Thank you. That is what I was trying to code even tho I see now that it has a problem, it won't match the last 3 chars CHC, but the other comment solved it.