Re: STDERR Restore after redirect

[choroba]

Store stdout and stderr to variables, restore them later. No select is needed.

#!/usr/bin/perl
use warnings;
use strict;

open my $fh, '>', '1.log' or die $!;
my $stdout = *STDOUT;
my $stderr = *STDERR;

*STDOUT = $fh;
*STDERR = $fh;

print "stdout 1\n";
warn "stderr 1\n";

*STDOUT = $stdout;
*STDERR = $stderr;

print "stdout 2\n";
warn "stderr 2\n";

[tultalk]

Appreciate response.

However, problem persists.

The filehandle you're printing on got itself closed sometime before now. Check your control flow. print() on closed filehandle

This makes no sense to me

[tultalk]

I blocked the call to sendmail and the handles were restored and the print command elsewhere executed.

# SendMail(%mail) or die $Mail::sendMail::error;

unblocking and

    #restore the file standard handles  
    *STDOUT = $stdout;
        *STDERR = $stderr;
    close($fh);
    print "stdout 2\n";

results in: print() on closed filehandle $fh at /home/abcus/public_html/httpsdocs/cgi-bin/lib/perl/manageusers.pm line 1124. stderr 2

So sendMail call is causing problem

ugh

[choroba]

print() on closed filehandle $fh 
#                            ~~~

But in the code, you just call print! So, $fh has been selected. The solution might be to

select $stdout;

after restoring stdout.

[poj]

sendMail call is causing problem

Yes, some minimal code to demo the problem. Fix is as choroba said.

#!/usr/bin/perl
use warnings;
use strict;

SendMemberMail();
print "stdout 2\n";

sub SendMemberMail {
  open my $fh, '>', '1.log' or die $!;

  MAIL: { 
    local *STDOUT = $fh;
    local *STDERR = $fh;

    print "stdout 1\n";
    warn "stderr 1\n";
    
    # equivalent Mail:Sendmail code
    open S,'>','socket' or die;
    my $oldfh = select(S); $| = 1; select($oldfh);
    close S;
  }
  close $fh;
 # select(STDOUT); # uncomment to fix
}

poj

[huck]

ahem, poj called it when he said

   # equivalent Mail:Sendmail code
    open S,'>','socket' or die;
    my $oldfh = select(S); $| = 1; select($oldfh);
    close S;

I saw it too when i looked at the SendMail code, he even used the same global filename and varlable that they did.

notice he says

# select(STDOUT); # uncomment to fix

Did you try that?

And notice he credits choroba for mentioning the fix first

select $stdout;

I am mentioning this AGAIN because i understand how frustrating it can be when "someone" skips the actual fix, and wanders away in all odd directions instead.

The trouble comes from my($oldfh) = select(S); $| = 1; select($oldfh); at http://cpansearch.perl.org/src/ABELTJE/Test-Smoke-1.72/lib/inc/Mail/Sendmail.pm. Note that at the time of my($oldfh) = select(S); the selected default output (while maybe seeming to be *STDOUT) is infact $fh via *STDOUT, so that reselect at the end points directly to $fh rather than back at STDOUT as you might think at first thought. See restoring *STDOUT = $stdout; doesnt do much good when the default print file is directly set to $fh by the select.

And just as a lark, seeing this

unless ( socket S, AF_INET, SOCK_STREAM, (getprotobyname 'tcp')[2] ) {
            return fail("socket failed ($!)")

brought back memories of doing things before i knew of use IO::Socket;, Hardly thought of in maybe 15 years, still works tho, well kinda. If you were to use low level sockets, (for some comparability reasons id suspect,) is there another way to unbuffer a file than to select it and set $|?