Matching escaped quoted strings

Here is a problem that may be harder or simpler than it looks.

The task is to extract double quoted strings from another string. For the string

    '"foo" & "bar"'
[download]

the matched strings would be "foo" and "bar" including the quotes.

The thing that makes this a little tricky is that double quotes in the quoted string are escaped using a pair of quotes. I think this escape format comes from Basic. Thus, the string " He said "maybe" " would be escaped as follows:

    '" He said ""maybe"" "'
[download]

This leads to some nice pathological cases such as '""""""""""' and '" """&" """'

Here is a test framework if you care to bend your brain to this puzzle. I'll post my own answer later.

Problem. Write a function find_quote() which takes a string and adds <> around the double quoted strings.

For example

    '"foo" & "bar"' -> '<"foo"> & <"bar">'
[download]

Double quotes within the string are escaped as a pair of double quotes. The quotes will always be balanced. Apart from double quotes there can be any arbitrary characters before or after the strings. The test below should demonstrate the types of string to expect.


    #!/usr/bin/perl -w

    use strict;

    use Test::More 'no_plan';


    # Test input and target output
    my %strings = (
                    ''                  => '',
                    '""'                => '<"">',
                    '""""'              => '<"""">',
                    '""&""&""&""&""'    => '<"">&<"">&<"">&<"">&<"">',
                    '""""""""""'        => '<"""""""""">',
                    '""""&""""'         => '<"""">&<"""">',
                    '"""&"""'           => '<"""&""">',
                    '"foo"&"bar"'       => '<"foo">&<"bar">',
                    ' "foo" & "bar" '   => ' <"foo"> & <"bar"> ',
                    '" "'               => '<" ">',
                    '"   ""   "'        => '<"   ""   ">',
                    '" """&" """'       => '<" """>&<" """>' ,
                    '" "" "'            => '<" "" ">',
                    '" "" "&" "" "'     => '<" "" ">&<" "" ">',
                    '" "" & "" "'       => '<" "" & "" ">',
                    '""&""""'           => '<"">&<"""">',
                    ' "" '              => ' <""> ',
                    ' """" '            => ' <""""> ',
                    '  ""&""&""&""&"" ' => '  <"">&<"">&<"">&<"">&<"">
+ ',
                    ' """""""""" '      => ' <""""""""""> ',
                    'test("foo","bar")' => 'test(<"foo">,<"bar">)',
                    );


    # Add your code here
    sub find_quote {

        my $str = $_[0];

        # Broken example
        $str =~ s/(".*?")/<$1>/g;

        return $str;
    }


    # Run the tests
    while (my($input, $result) = each %strings) {
        is(find_quote($input), $result, "for string:\t" . "'$input'");
    }
[download]

--
John.

Comment on Matching escaped quoted strings Select or Download Code
•Re: Matching escaped quoted strings by merlyn (Sage) on Feb 19, 2004 at 17:43 UTC
Untested, but this is a straightforward problem: `sub find_quote { local $_ = shift; s/("([^"]+\|"")*")/<$1>/g; $_; }` [download] -- Randal L. Schwartz, Perl hacker Be sure to read my standard disclaimer if this is a reply.	[reply] [d/l]
Re: Matching escaped quoted strings by Abigail-II (Bishop) on Feb 19, 2004 at 17:54 UTC
`use Regexp::Common; s/$RE{delimited}{-delim => '"'}{-esc => '"'}{-keep}/<$1>/g;` [download] Abigail	[reply] [d/l]
Re: Re: Matching escaped quoted strings by ysth (Canon) on Feb 19, 2004 at 18:31 UTC
Regexp::Common is delightful; that produces the quite nice: `(?-xism:((\")([^\"](?:(?:\"\")[^\"])*)(\")))`	[reply] [d/l]
Re: Matching escaped quoted strings by jmcnamara (Monsignor) on Feb 19, 2004 at 21:15 UTC
Nice answers. merlyn's in particular. I was definitely overthinking or underthinking the problem. Here is my take for the record. `sub find_quote { my $str = $_[0]; my $c; $str =~ s/( (?{$c = 1}) ".*?" (?{$c++}) (?(?{$c % 2 == 0})(?!")\|^) ) /<$1>/xg; return $str; }` [download] -- John.	[reply] [d/l]


Think about Loose Coupling
	PerlMonks

Matching escaped quoted strings

What level of existential comfort do you require?