The key is in the glob function. If you feed it a string like "{1,2}{a,b,c}" it creates all combinations of elements within the braces. Here is a complete solution for your problem. I hope you can adapt it to your needs. There is nothing really new in there.

use strict;
use warnings; 
use File::Glob qw{bsd_glob};

my $string;
my $entry;
do {
  print"\n\n Press 1 to Enter New File or 2 to Combine:  ";
  $entry=<STDIN>; chomp $entry;  
  if ($entry==1) { 
    print"\n\n    Enter New File Name (.txt):  "; 
    my $filename = <STDIN>; 
    chomp $filename;
    open my $fh, "<", $filename or die "Cannot open $filename.\n";
    my $DNA;
    {
      local $/=undef;
      $DNA = <$fh>;
    }
    close $fh;
   
    chomp $DNA;
    $DNA=~s/\n/,/g;
    $string .= "{$DNA}";
  }      # Curly brace for entry1 ends:  
} until ($entry==2);
for (bsd_glob $string) {
  print "~$_~\n";
}
[download]

So for every file you input, it creates this substring "{...,...,...}" with all elements from the file and adds it to the previous substrings of the same kind. When you are done, the overall string is fed into glob to create all combinations. I hope this makes it clear.