comment on

Your original string contains 9 characters. The form you are compressing to packs 4 characters to a byte, but with no way of knowing how many characters in the last byte are significant.

Update: FWIW you can speed this up considerably by banging 4 characters at a time -- code enclosed, below. However, in my experience a little bit of C will do a lot better -- particularly when reading big chunks of file and getting the C to process many strings at a time.

# ACGT String compression and decompression
#
# We compress to fixed length string, 2 bits per symbol -- zero fill i
+n last byte.

my %compress ;    # string of up to 4 characters to compressed item
my @expand ;      # compressed value to string

BEGIN {
  my @ACGT = qw(A C G T) ;
  my $s = '' ;
  my $v = 0 ;
  foreach my $a (@ACGT) {
    $s = $a ; $compress{$s."\n"} = $compress{$s} = chr($v) ;
    foreach my $b (@ACGT) {
      $s = $a.$b ; $compress{$s."\n"} = $compress{$s} = chr($v) ;
      foreach my $c (@ACGT) {
        $s = $a.$b.$c ; $compress{$s."\n"} = $compress{$s} = chr($v) ;
        foreach my $d (@ACGT) {
          $s = $a.$b.$c.$d ;
          $compress{$s} = chr($v) ;
          $expand[$v++] = $s ;
        } ;
      } ;
    } ;
  } ;

  $compress{"\n"} = '' ;
  $compress{''}   = '' ;
} ;

# Compress ACGT string (all upper case) with or without trailing "\n"
#
#   $compressed = acgt_compress(ACGT_STRING)

sub acgt_compress {
  my $c = '' ;
  $c .= $compress{$_} for unpack('(a4)*', $_[0]) ;
  return $c ;
} ;

# Decompress compressed ACGT, and cut to required length
#
#   $acgt_string = acgt_expand(COMPRESSED, LENGTH)

sub acgt_expand {
  my $e = '' ;
  $e .= $expand[$_] for unpack('C*', $_[0]) ;
  return substr($e, 0, $_[1]) ;
} ;
[download]

In reply to Re: Unpack Fail to Decompress String? by gone2015
in thread Unpack Fail to Decompress String? by neversaint

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


We don't bite newbies here... much
	PerlMonks