perlmeditation
liz
This came up on perl5-porters this week:
<P>
The question is, when does the object get destroyed given this code?
<code>
if (my $object = Foo->new) {}
print "after if\n";
package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
</code>
Well, contrary to expectation (well, at least mine), the object does <B>not</B> get destroyed until global destruction! As the following output shows:
<code>
CREATED Foo=HASH(0xfc65c)
after if
DESTROYED Foo=HASH(0xfc65c)
</code>
instead of the expected:
<code>
CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
</code>
It appears that this behaviour is intentional and goes back until at least 5.00504. It is caused by the fact that any lexical inside an if() gets a refcount of 2, rather than of 1.
<P>
If this really is a problem for you, then there is the [cpan://Internals] module which allows you to set the refcount of a variable from Perl.
<code>
use Internals qw(SetRefCount);
if (my $object = Foo->new) { SetRefCount( $object,1 ) }
print "after if\n";
package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
__END__
CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
Attempt to free unreferenced scalar: SV 0xfc65c.
</code>
Note that the object now <B>is</B> destroyed at the end of the <code>if()</code>, but that we get a warning at global destruction as a bonus.
<P>
Of course, there is a much simpler method: just add an extra scope!
<code>
{
if (my $object = Foo->new) { }
}
print "after if\n";
package Foo;
sub new { my $self = bless {},shift; print "CREATED $self\n"; $self }
sub DESTROY { print "DESTROYED $_[0]\n" }
__END__
CREATED Foo=HASH(0xfc65c)
DESTROYED Foo=HASH(0xfc65c)
after if
</code>
<P>
Hope this maybe helpful for someone someday.
<P>
Liz