my %h = (
  rock   => 3,
  candle => 25,
  bug    => 3,
  rain   => 12,
  dust   => 17,
  spider => 12,
);

for( sort { $h{$b} <=> $h{$a} || $a cmp $b } keys %h ) {
  print "$_ => $h{$_}\n";
}

__output__

candle => 25
dust => 17
rain => 12
spider => 12
bug => 3
rock => 3
[download]

That works perfectly, you're the best!! Thanks so much for your help broquaint!!

Use following code for sorting

Temporary variable is not needed of course

While your code works, it's one of those occasions where you're making code less readable by being more explicit.

...
    sort {  $h{$b} <=> $h{$a}  ||  $a cmp $b  }
    keys %saved_key;
[download]

Unlike C or Java, the Perl operator || keeps the actual true value. (C or Java would just return 1; but they don't have <=> either.) This means (among other things) that Perl can cascade a number of possible criteria in a single statement. By avoiding the visual clutter of temporary variables and unnecessary checks against zero, your code can be more readable.

This is the Perl idiom. List each criteria from most important to least important. The first criteria which returns a -1 or 1 will decide the sort order; any criteria returning 0 will fall through to the next part of the expression.

my @sorted = 
    sort {          $hash{$b}  <=>  $hash{$a}          ||
                           $a  cmp  $b                 ||
                     func($a)  <=>  func($b)           ||
             $other{name}{$b}  cmp  $other{name}{$a}    }
    @unsorted;
[download]

I find that a newline after each criteria helps the reader immediately understand what's going on. (The extra spacing on each line is optional.)

This newline on each phase technique is useful of any of the Perl-style "list pipelines" which are common, such as those with colorful names like the Schwartzian Transform or the Orcish Maneuver.

--
[ e d @ h a l l e y . c c ]

If you want the hash to come out in the order it was created, than Tie::IxHash is probably for you ( and if you need speed look at Tie::Hash::Indexed which is written in XS ). Do not use these modules if you need your hash sorted though. While it does provide 3 methods to resort the hash (user provided key list or ASCIIBetically by keys/values), it does not provide any mechanism for retaining auto-sorting new keys/values.

#!/usr/bin/perl
use strict;
use warnings;
use Tie::Hash::Sorted;

my $sort = sub {
    my $hash = shift;
    [ sort { $hash->{$b} <=> $hash->{$a} || $a cmp $b } keys %$hash ];
};
tie my %sorted_data, 'Tie::Hash::Sorted', 'Sort_Routine' => $sort;
%sorted_data = (
    rock => 3, candle => 25, bug => 3,
    rain => 12, dust => 17, spider => 12
);
print "$_ : $sorted_data{$_}\n" for keys %sorted_data;

[download]

Cheers - L~R

foreach (sort { ($saved_key{$b} <=> $saved_key{$a}) || ($a cmp $b) } keys %saved_key)