#!/usr/bin/perl
use strict;
use warnings;

use Algorithm::Loops qw( NestedLoops );

# Sum together subsets of these items:
my @items= reverse 1..9;

# The sum we wish to acheive:
my $target= 20;

# $sum[$N] == sum of first $N selected items:
my @sum = 0;

# Build an iterator that returns only lists of
# indices for subsets that match our target sum:
my $iter= NestedLoops(
    [
        # First loop: all item indices
        [ 0..$#items ],

        # @items-1 subsequent loops:
        ( sub {
            # If we need more items:
            $sum[@_] < $target
                # then get more (unique) item indices
                ? [ ($_+1)..$#items ]
                # else don't get more items
                : []
        } ) x $#items,
    ],
    {
        # Determine which subsets to return:
        OnlyWhen => sub {
            # Compute sum of selected items as
            # sum of @_-1 items plus last item:
            $sum[@_]= $sum[$#_] + $items[$_[-1]];

            # Return subsets that match desired sum:
            return $sum[@_] == $target;
        },
    },
);
# For each desired list of indices, get subset of items:
while(  my @list= @items[ $iter->() ]  ) {
    warn "$target = sum( @list )\n";
}