I don't get map. How would I use map here?

[Plankton]

I just can't seem to ever understand map. I know the two for loops below could be rewriten with map. Could someone help me out here?

#!/usr/local/bin/perl -w
use strict;

my %byFile;

for (<DATA>) {
        my ( $size, $name ) = split /\s+/;
        $byFile{$name} = $size;
}

for ( keys %byFile ) {
        print "$_\t=>$byFile{$_}\n";
}
__DATA__
0       5713813
276k    CVS_RES
264k    Desktop
17k     Documes
33k     SEARCH

Thanks!
<update>Sorry for not be clearer in the first place, but I do need to use %byFile for other purposes. The script I posted just demostrates some isolated code I have in another script.

[Zaxo]

The first can be written, my %byFile = map { reverse split } <DATA>; That relies on the data being reliable in format.

The second can be mapped, too, but I'd more likely write it either the way you have it, or else as while (my ($key, $val) = each %byFile) { . . .  }. Here is a mapped version, print map {"$_\t=>$byFile{$_}\n"} keys %byFile; I'd favor the "while each" version because it is more sparing of memory, and the results are not likely needed elsewhere.

[NetWallah]

The key thing to understand is that map returns a list.

If you do not need a list returned, (which is the case in your example),use for.

Update:Style suggestion:
Your second loop is better written as

while (my ($k,$v) = each %byFile ) {
        print "$k\t=>$v\n";
}

This is more idiomatic, uses less memory, and is faster than your loop.

[jeffa]

Have you read Map: The Basics yet?

[duff]

Here's one way to use map for what you want:

#!/usr/bin/perl

use strict;

print map { "$_->[1]\t=>$_->[0]\n" } map {  [ split ] } <DATA>;

__DATA__
0       5713813
276k    CVS_RES
264k    Desktop
17k     Documes
33k     SEARCH

But the magic really isn't so much in the map as it is in the use of an anonymous array.

[Eimi Metamorphoumai]

Personally, I wouldn't use map in either of those places. Definitely not in the second, since it would be evaluating it for side effects only. For the first you could use

%byFile = map {(split /\s+/)[1,0]} <DATA>;

with the proviso that it would remove anything already in %byFile. That is, it would take each element from DATA and translate it into two elements, creating a list of pairs to be treated as a hash. But I still don't think this is a great place for map, because it's not as easy to read (and quite a bit more confusing).

[Fletch]

Use map to transform one list of values into a new list; use for to iterate over a list performing some operations. In both of your cases you're not really generating a new list. The first one could be done as  my %byFile = map { chomp; split( /\s+/, $_, 2 ) } <DATA>, but I'd personally use the for instead. Considering your second loop is a single statement I'd probably write it as print "$_\t=>$byFile{$_}\n" for keys %byFile, but definately not using map.

[eric256]

Neither realy needs to be a map. However you could make the second one a map like the following:

map { print "$_\t=>$byFile{$_}\n"; } keys %byFile;

[duff]

map in void context still rankles me for some reason (even though I understand that perl now has an optimization for it). So I'd write that as one of these:

print map { "$_\t=>$byFile{$_}\n" } keys %byFile;

or

print "$_\t=>$byFile{$_}\n" for keys %byFile;  # look Ma! no map!  :-)

[pbeckingham]

First I'd reduce your two loops to one:

  while (<DATA>)
  {
    print "$2\t=>$1\n" if /^(.*?)\s+(.*?)$/;
  }

  __DATA__
  0       5713813
  276k    CVS_RES
  264k    Desktop
  17k     Documes
  33k     SEARCH

Then I'd substitute the map for the for:

  map {print "$2\t=>$1\n" if /^(.*?)\s+(.*?)$/} <DATA>;

  __DATA__
  0       5713813
  276k    CVS_RES
  264k    Desktop
  17k     Documes
  33k     SEARCH

As long as you are okay with there being a serious loss in readability, and it smacks of golf.

[Chady]

One OT but related note is the use of for to read from a filehandle.

I got bitten by that before.

for will create the list and iterate over it. This means that if <DATA> is a filehandle to a file containing 1Gb of data, for will attempt to create the 1Gb+ list, thus bringing your system to its knees.

The 'safer' way to do this would be to use a while instead of for because it doesn't create the list.

[ryantate]

Not sure if you're looking to replace both loops entirely or whether you need %byFile for other purposes ...

print map {join("\t=>", reverse split) . "\n"} <DATA>;

Update: replaced superflous foreach after print

[Not_a_Number]

Update: replaced superflous foreach after print

You could also remove the superfluous map :-)

print join ( "\t=>", reverse split ) . "\n", <DATA>;

Update: Sorry, ignore

[Roy Johnson]

Not without putting it in a different loop:

print join("\t=>", reverse split), "\n" while <DATA>;