RE: lexical weirdness(?)

[dchetlin]

in reply to lexical weirdness(?)

As the anonymous but wise monk pointed out above, this is a case of the `my $x if 0' feature. For some reading material on this, start here and look through some of the p5p threads on it.

I doubt this feature will go anywhere for Perl 5 at least, because it doesn't seem to cause any problems and allows you to do something (create a static variable) which you can't really do any other way.

But it does mean you should be careful when declaring lexicals.

-dlc

[jimt]

Thanks for the help guys. I'll begrudgingly admit that this does make sense, though I'm not too pleased with it.

Regardless, just to be good and point it out, my $x if 0; is most certainly not the only way to create a static variable. This is clearer, IMHO, and more widely used. (I hope)


{
    my $static;
    sub some_function {
        print "Static!", $static++;
    };
};


Just wrap up the function in braces and lexically scope any "static" variables you want in the enclosing braces. Much clearer, IMHO.

[dchetlin]

There are at least two major differences between closures and static-via-my-if-0 variables.

Here's the first. Look closely at this code and see if you can figure out what its output will be before you run it.

#!/usr/bin/perl -w
use strict;

{
    my $closure;
    sub func_w_closure {
        print "Closure! ", $closure++, "\n";
        func_w_closure($_[0]+1) if $_[0] < 3;
    }
}

sub func_w_static {
    my $static if 0;
    print "Static! ", $static++, "\n";
    func_w_static($_[0]+1) if $_[0] < 3;
}

func_w_closure(0);
func_w_static(0);

I'll use tilly's spoiler trick:

[~] $ dev/test/scope.pl Closure! 0 Closure! 1 Closure! 2 Closure! 3 Static! 0 Static! 0 Static! 0 Static! 0

In other words, the closure is the same variable through all calls, including recursive ones, while each recursive call to the func_w_static gets its own copy.

The cool thing about that, of course, is that if you call func_w_closure again, you see that each recursive instance keeps its value!

The other difference is that closures can be shared among functions -- if you stick another function into the lexical scope of `$static' above, some_function and your new function will refer to the same variable.

-dlc