1) There are modules (search CPAN for "INI") that can help you here. Let's forget that given this is an excercise.

2) I don't think you want a hash. Don't you want a list (read array) of records (read hash)?

my @list;

while (@art) {
   my $record = {
      "art"          => shift(@art),
      "produce"      => shift(@produce),
      "price"        => shift(@prices),
      "descriptions" => shift(@descriptions),
   };

   push(@list, $record);
)

print("We have ", scalar(@list), " models for sale.\n");
print("\n");
print("They are:\n");
foreach (@list) {
   print("Model:       ", $_->{"art"}, "\n");
   print("Produced by: ", $_->{"produce"}, "\n");
   print("Price:       $", $_->{"price"}, "\n");
   print("Desc:        ", $_->{"descriptions"}, "\n");
   print("\n");
}
[download]

Update: Typed printf where I should have typed print. Fixed

hey!
Thanks for your reply!

1) Do you mean App::Serializer::Ini ?
2) You're right!! I know it but I doesn't know how to do it ;-)

Config::IniFiles and Config::IniHash are more generic, but if App::Serializer::Ini does the trick, excellent. I haven't used any of these.

Your code is also not very efficient in that you're looping through the contents of the file four times. You also don't need to read the whole file into a list before processing it. Finally, you can take a shortcut and instead of checking individually for each valid key (e.g. "produce", "price", etc.), you can just take whatever is before the equals sign as a key and whatever is after as the value.

open(FILE,"<$file") or die $!; # always check for the error condition!
while (my $line = <FILE>) {
  if ($line =~ m/\[(.*)\]/) {
    push @art, { item => $1 };
  }
  elsif ($line =~ m/^(\w+)\s*=\s*(.*?)\s*$/) { # the \s*'s ignore lead
+ing and trailing whitespace.
    $art[-1]->{$1} = $2; # [-1] references the last item in the array;
+ i.e. what you just pushed on there
  }
}
close FILE;
[download]

• Check the "perlvar" man page to read about the "INPUT_RECORD_SEPARATOR" variable, "$/". You can set it to read each block of lines (up to the next blank line) instead of one line at a time, so each element of your "@all" array contains a full config record.
• Look up the "split" function (perldoc -f split). After reading each block of lines into each array element, separate the lines ( split /\n/ ), then split each non-initial line into "attribute" and "value" ( split /=/ ).
• You can load your array of hashes while reading the file, so you don't end up with two copies of the data in memory and you don't need to do repeated loops over the same set of data.

At the risk of short-cutting your exploration of the essential man pages, it could end up looking like this:

my @AoH_attribs;

open( FILE, "<$file" );
{
   local $/ = '';  # empty string is "magic" for "paragraph-mode"

   while (<FILE>)   # read a group of lines into $_
   {
      my %hash = ();
      my $itemname = ( /^\[(.*?)\]/ ) ?  $1 : 'NO_KEY';
      next if ( !/=/ or $hashkey eq 'NO_KEY' );

      $hash{item} = $itemname;

      for my $line ( split /\n/ ) {
         next unless ( $line =~ /=/ );

         my ( $attrib, $value ) = split /=/, $line;
         $hash{$attrib} = $value;
      }
      push @AoH_attribs, { %hash };  # note use of curly braces
   }
}
close FILE;

# now, @AoH_attribs contains a list of hash refs, one for each input b
+lock;
# you can access each hash like this:

for my $itemref ( @AoH_attribs ) {
   my %itemhash = %$itemref;
   print "$_ = $itemhash{$_}\n" for ( sort keys %itemhash );
   print "\n";
}
[download]

(update: fixed syntax error in code)

#!/usr/bin/perl
use strict;
use warnings;
use Data::Dumper;

my %chips;
{
    local $/ = "";

    while(<DATA>) {
        chomp;
        # Capture chip name in $1 and delete line with chip name
        s/^\[([^\]]+)\]\n// or die "error: ...";
        $chips{$1} = {split /[\n=]/};
    }
}

print Dumper \%chips;

__DATA__
[Athlon 4000+]
price=300 euro
produce=AMD
description=Fast

[Celeron 3000]
price=200 euro
produce=Intel
description=Slower

[download]

Much depends on what you mean by "etc...". By calling your data structure "%hash" (which isn't very descriptive) and stopping right when things got interesting (i.e., how do you handle multiple values that share the key "item"), you've left the problem in an ambiguous state. Part of advancing past newbyness is learning to drive out ambiguity when thinking through what you need to do.

Since in the data you've shown, several strings will end up sharing the "item" key, I suspect that you want individual anonymous hashes, one per group, each having a single "item" key. If this is true, then you want to parse the text into a structure that looks like

my $data = [
  {
    item => 'Athlon 4000+',
    price => '300 euro',
    ...
  },
  {
    item => 'Celeron 3000',
    price => '200 euro',
    ...
  },
  ...
];
[download]

Does this help?