substituted text is being interpreted

[j.goor]

Hi,
When I substitute a variable (scalar), it appears that the
text has been interpreted in stead of just being replaced:
e.g:

$var = '<a href="somefilename(x)withanumberedhash.htm#666">';
s@$var@$somethingelse@;

How come? (and what to do about it?)
Rgds, John

[gopalr]

Hi,

what dragonchild said is correct... What variable are you substituting on?

if Metacharacter found inside the variable use 'quotemeta' or '\Q' and '\E'

$line='Sampel Text <a href="somefilename(x)withanumberedhash.htm#666">
+';
$somethingelse='ok';
$var = '<a href="somefilename(x)withanumberedhash.htm#666">';

$var=quotemeta($var);
$line=~s@$var@$somethingelse@;

or

$line=~s@\Q$var\E@$somethingelse@;

[ccn]

use \Q, \E modifires in the regexp. see perldoc perlre

[holli]

mmh.
this runs as expected:

$somethingelse="AA";
$var = 'BB';
$_ = 'beforeBBafter';
s@$var@$somethingelse@;
print; #prints "beforeAAafter"

but this does not:

$somethingelse="AA";
$var = '<a href="somefilename(x)withanumberedhash.htm#666">';
$_ = 'before<a href="somefilename(x)withanumberedhash.htm#666">after';
s@$var@$somethingelse@;
print;

and that is because of the braces() which are regex special chars. if you

$somethingelse="AA";
$var = '<a href="somefilename\(x\)withanumberedhash.htm#666">';
$_ = 'before<a href="somefilename(x)withanumberedhash.htm#666">after';
s@$var@$somethingelse@;
print;

it works fine.

[wolfger]

Interesting. I thought using single quotes meant you didn't have to escape special characters. Is this because the regex grabs the single quoted text and then interprets it as a normal (double-quoted) expression?

[dakkar]

It's a bit subtler than that.

When you write string literals, single-quoting them make them contain exactly the characters you typed, while double-quoting them activates the interpolation mechanism.

On the other hand, when you use a string as a regular expression, it gets interpreted by the regex engine.

For example:

$literal='abc@array$';
@array=(1,2,3);
$interpolated="abc@array\$";

print 'literal: ',$literal,"\n";
print 'interp.: ',$interpolated,"\n";

if ($literal =~ /$literal/) {
  print "literal matches itself\n"
} else {
  print "literal doesn't match itself\n"
}

$literal2='abc@array';
if ($literal2 =~ /$literal2/) {
  print "literal2 matches itself\n"
} else {
  print "literal2 doesn't match itself\n"
}

if ($literal2 =~ /$literal/) {
  print "literal2 matches literal\n"
} else {
  print "literal2 doesn't match literal\n"
}

This prints:

literal: abc@array$
interp.: abc1 2 3$
literal doesn't match itself
literal2 matches itself
literal2 matches literal

The first two lines are hopefully obvious. As for the others:

• $literal does not match itself because, seen as a regexp, it requires the string it matches to end with a y (the $ is interpreted by the regexp engine)
• $literal2 does match itself. This is to confirm that the regexp is not "double-quote-interpolated-expanded-whathaveyou": the @ is still a single character.
• $literal2 matches $literal because it does end in a y.
OK, for the pedants: the string between the // is interpolated, but its contents are not further expanded. I felt that this was more noise than signal, in this case.

[dave_the_m]

s@$var@$somethingelse@

I presume you want the replacement text to be the literal string '$somethingelse', rather than the contents of the variable. The replacement text in substitutions behave like double-quoted strings, which cause interpolation. To avoid this, either use single quotes, or escape the $, eg

s{$var}'$somethingelse';
s@$var@\$somethingelse@;

Dave.

[duff]

I'm sorry, but you're example doesn't elucidate your problem (at least for me). What do you mean by "the text has been interpreted"? What does your example do that you expect it to not do or vice versa?

update:Ah, I think ccn has the sense of it. Some of the characters in your string are special WRT the regular expression engine (and presumably you want them to be treated as-is). You can use quotemeta or \Q as ccn says.

[dragonchild]

What variable are you substituting on? Regular expressions don't operate in a void, you know.

[holli]

yes, they do. if no variable is given, then they operate on $_.

[dragonchild]

Very true, but where is $_ referenced in the OP?

[j.goor]

Hi All,
quotemeta did the trick!!
Thanx for meditating! I feel actually enlightened! Wheeeee!!! ... ehhh.. I mean "Hummmmmmmmmmmmm" ;-)
Rgdz,
John