How much can a function know about the context in which it is called?

[jacques]

I have a bunch of calls to the same function. The function ultimately prints to STDOUT. I want to change the function to return a string rather than print it. So that I can say:

print function(); # prints the string that function returns.

Easy enough. But instead of putting the print before the funtion call, I would like to simply say:

funtion(); # prints string since not assigned 

$value = funtion(); # Does not print. $value holds the return string.

In other words, I want function() to know the context in which it is called, so that it knows whether to print a string or to return one. And I don't want to use IO::Scalar.

Is this possible?

[friedo]

Certainly. The unfortunately named wantarray function can tell you:

Returns true if the context of the currently executing subroutine or eval() block is looking for a list value. Returns false if the context is looking for a scalar. Returns the undefined value if the context is looking for no value (void context).

[Joost]

print() enforces list context on the function, so you can do

sub function { 
    defined wantarray ? $string : print $string 
}

see wantarray.

update: I used defined so can also do

my $string = function();

this does prevent you from checking print()'s return code, though.

[ikegami]

Use wantarray:

sub test {
   print(defined(wantarray)?1:0, " ");
   print(wantarray?1:0, "\n");
}

test();       # 0 0
$a = test();  # 1 0
@a = test();  # 1 1

sub function {
   my $rv = "Hello World";

   if (defined wantarray) {
      return $rv;
   } else {
      print("$rv\n");
      return;
   }
}

function();              # Hello World

my $greet = function();
print("[$greet]\n");     # [Hello World]

[Corion]

If you are not afraid to use a module by TheDamian, Contextual::Return can take out much of the uglyness that wantarray syntax imposes.

[jacques]

Thanks everyone.

[brian_d_foy]

Note that the context doesn't tell you what happens with the return values or what the user wants to do.

For instance, in this common idiom, function() is in list context but I want to the output in @values, not printed. I wouldn't like functions that try to be smarter than me.

my @values = map { function( $_ ) } @input;

Every time I've thought it would be good to simply print to STDOUT, someone comes along and wants the output in some other way. Instead of making the function know that stuff, I let the user decide. I can always make a print_function() that does that and still lets me use the "dumb" version/ :)