Params::Validate and Test::MockObject::Extends

[badaiaqrandista]

Hi all,

I am trying to write test for the application I am maintaining. It has a lot of OO modules. To start, I created a test like this for one of those modules (modified from the original code):

#!/usr/bin/perl

use strict;
use warnings;

use Test::MockObject::Extends;

my $mock_property = Test::MockObject::Extends->new('MyApp::Property');
$mock_property->mock('id', '1');
$mock_property->mock('su_pwd', 'password');

my $admin = MyApp::Admin->new(owner => $mock_property, id => 0);
is_deeply(
    $admin, 
    {
        admin_id => 0,
        domain_id => '1',
        firstname => 'Super',
        lastname => 'User',
        username => 'su',
        password => 'password',
    },
    "new() with id eq '0' (superuser)"
);

-----------------------------------

package MyApp::Admin;

use strict;
use warnings;

use Params::Validate ':all';

sub new
{
    my $class = shift;
        my %args = validate(@_,
        id => { type => SCALAR },
        owner => { isa => 'MyApp::Property' },
    );

        my $self = bless {
        admin_id => $args{id},
        domain_id => $args{owner}->id,
        firstname => 'Super',
        lastname => 'User',
        username => 'su',
        password => $args{owner}->su_pwd,
    }, $class;

    return $self;
}

When I run the test, it breaks with Params::Validate error saying that 'owner' parameter is an object of 'T::MO::E::a', not 'MyApp::Property'. I guess this is because Params::Validate does not validate the 'owner' parameter by calling 'isa', but checking the perl's internal data structure to check 'isa'.

Is there anyway to go around this? Or do I have to create my own mock object library?

Thanks

[chromatic]

Params::Validate is broken. (I read its code; both the pure Perl and XS code have the same bug.) It thinks that UNIVERSAL::isa is a function. (It's not. It's a method.)

Which version of Test::MockObject::Extends are you using? Newer versions use UNIVERSAL::isa which tries to work around this problem and attempts to reveal which code is broken, buggy, and wrong.

(Of course, if you're using the XS version of Params::Validate, you'll never see the error message because UNIVERSAL::isa doesn't have hooks that deep.)

[diotalevi]

There's an option you can set to force the use of the pure perl, non-XS Params::Validate. It sounds like the easiest thing to do is force plain perl Params::Validate and then use UNIVERSAL::isa.

[badaiaqrandista]

I use Test::MockObject::Extends version 0.20 and Params::Validate version 0.76, both of them come with debian stable.

Anyway, I have found a workaround. I have changed the test script like this:

#!/usr/bin/perl

use strict;
use warnings;

use Test::MockObject;

my $mock = Test::MockObject->new;
$mock->fake_module(
    'MyApp::Property',
    new => sub { bless {}, 'MyApp::Property' },
    id => sub { 1 },
    su_pwd => sub { 'password' }
);

my $mock_property = MyApp::Property->new;

my $admin = MyApp::Admin->new(owner => $mock_property, id => 0);
is_deeply(
    $admin, 
    {
        admin_id => 0,
        domain_id => '1',
        firstname => 'Super',
        lastname => 'User',
        username => 'su',
        password => 'password',
    },
    "new() with id eq '0' (superuser)"
);

[autarch]

Gee, thanks for the bug report. Oh, you didn't bother sending one!

The XS version actually uses the Perl API's sv_derived_from() function, which apparently is like calling UNIVERSAL::isa(). You might want to submit a doc patch for the Perl core warning people off from using it if you really want to promote "proper" use of isa() and can().

[badaiaqrandista]

Sorry, I've never filed a bug report before. And I thought it was my fault. Anyway, what do you mean by 'proper' use of isa() and can()?