Re: Adding functionality to an Object

[broquaint]

in reply to Adding functionality to an Object

If you're looking for a quick and dirty solution and you're working with your own (hash-based) objects this should do the trick:

use strict;
use warnings;

use Test::More tests => 9;

{
  package root;

  sub base { "do" }

  package foo;

  @foo::ISA = 'root';

  sub new { bless {@_[1 .. $#_]}, $_[0] }

  sub hey { 'yo' }
}

sub add_method_to_class {
  my($cls, $name, $meth) = @_;

  no strict 'refs';
  *{"$cls\::$name"} = $meth;
}

sub add_method_to_obj {
  my($obj, $name, $meth) = @_;

  my $class   = ref $obj;
  (my $objcls = "$obj") =~ s/[^A-Z0-9]//ig;

  {
    no strict 'refs';
    *{"$objcls\::ISA"} = [ @{"$class\::ISA"}, $class ];
  }

  $_[0] = bless { %$obj }, $objcls;
  add_method_to_class($objcls, $name, $meth);
}

can_ok foo => 'hey';
can_ok foo => 'base';
eval { foo->new->yay }
  or pass "foo can't yay";

add_method_to_class('foo', yay => sub { "yay!" });

can_ok foo => 'yay';

my $o = foo->new;
eval { $o->woo }
  or pass "\$o can't woo";

add_method_to_obj($o, woo => sub { "woo!" });

can_ok $o => 'woo';
eval { foo->new->woo }
  or pass "foo can't woo";

can_ok $o  => 'base';
can_ok $o  => 'hey';

But if you're looking for a long-term robust solution then follow the sagacious davorg's advice.