read file into scalar

[Anonymous Monk]

Hi, how do I read a file straight into a scalar?

open PAGE, '<', $success or die "Can't open  $success : $!";
flock (PAGE, 1) or die "Can't lock $success for reading: $!";
my $page = <PAGE>;
close PAGE;

only seems to read the first line. I know I can read it into an array, but I don't want that...

[Limbic~Region]

Anonymous Monk,
That is because in scalar context, the angle bracket operator (see also readline) uses $/ (see perlvar) to return a single line. To get it to read the entire file, simply undef it (locally of course).

my $page;
{
    local $/;
    open(my $fh, '<', $file) or die $!;
    $page = <$fh>;
}

[davido]

do{...} is a nice way to encapsulate the process.

my $page = do {
    local $/;
    open my $pagefile, '<', $success or die $!
    <$pagefile>;
};

[imp]

You can change the special $/ variable to enable 'slurp mode'.

open PAGE, '<', $success or die "Can't open  $success : $!";
flock (PAGE, 1) or die "Can't lock $success for reading: $!";
local $/;
my $page = <PAGE>;
close PAGE;

[jdporter]

I often to this:

my $text = do { local( @ARGV, $/ ) = ( $file ); <> };

although it's not as robust as the other solutions which die on error.

[arkturuz]

Use File::Slurp. It has everything you need for simple file reading and writing, and the most simplified interface.

[mickeyn]

follow an advice from 'Perl Best Practices' and use Perl6::Slurp.

Enjoy,
Mickey

[arkturuz]

I follow my advice not to mess with unfinished programming languages and to-be-announced features :-)
Anyway, thanks for the advice, I'll explore it.

[ysth]

Everything you need except for locking, which this OP seems to need. Though if a lock isn't needed for the whole read/update data/write cycle, File::Slurp's atomic option may be enough.

[tsee]

Hi,

perhaps you're doing it just for brevity, but I can't resist pointing out that it's a very bad idea to use flock() with numeric constants (e.g. 1). You should use the Fcntl module and import the flock constants:

use Fcntl qw/:flock/;
... open
flock($fh, FLOCK_EX);
# or:
flock($fh, FLOCK_SH);
...

Aside from being portable, it has the added benefit of being more friendly on the eyes and less demanding to your memory.

Steffen