Perl/Tk BrowseEntry delete method [request for example]

[scopey]

Could anyone supply example code for BrowseEntry's 'delete' method? I'm trying to use a "Delete" button widget to invoke the delete method on the current selection. Another way to describe my problem: how could BrowseEntry, it's delete method, it's -browse2cmd option and some Delete button all work together? Sorry if this sounds vague, I'm a Tk newbie. Thank you!

[zentara]

I would probably go the route of manipulating the -choices array.

#!/usr/bin/perl -w
use strict;
use Tk;
use Tk::BrowseEntry;

my $mw = MainWindow->new();

my $sel = '';
my @choices = qw(1 2 3 4 5 6 7);

my $mb;  #declare it first so can call it in callback
$mb = $mw->BrowseEntry(
 -label    => 'List One',
 -choices  => \@choices,
 -variable => \$sel,
 -browsecmd=>sub{
      #print "@_\n";
      my $selected = $_[1];
      #print "$selected\n";
      @choices = grep { $_ ne $selected } @choices; 
      $mb->configure(-choices => \@choices);
#      print "@choices\n"; 
                 }
)->pack();

MainLoop;

[thundergnat]

Or, you could manipulate the listbox directly using Subwidget.

use strict;
use warnings;
use Tk;
use Tk::BrowseEntry;

my $var;

my $mw    = MainWindow->new;
my $frame = $mw->Frame->pack;
my $be    = $frame->BrowseEntry( -label => "Label", -variable => \$var
+ );
$be->insert( 'end', "opt$_" ) for ( 0 .. 20 );
$be->pack( -pady => 5 );

my $lb = $be->Subwidget('slistbox');

my $bu = $frame->Button(
    -text    => 'Delete Selected',
    -command => sub {
        $be->delete( $lb->curselection ) if $lb->curselection;
        $var = '';
    },
)->pack( -pady => 5 );

MainLoop;

[TomKane]

Hey, thanks thundergnat. I didn't know about the Subwidget function of the tk::browseentry. It wasn't obvious to me from the documentation. I must have skimmed over a critical part and missed it. That lets me use the browse2cmd option and get the curselection() with the regular listbox function. I'm not a newbie anymore, but I've still got a lot to learn about the perl infernals. Tom