"defined" in while loop Edit | Delete | Quote | Reply | Private Reply

[manish.rathi]

This node falls below the community's threshold of quality. You may see it by logging in.

[targetsmart]

to make your code understandable by monks just see here before posting Markup in the Monastery

[moritz]

perlsyn gives some answers to your questions, scroll down to which is Perl short-hand for the...

[ELISHEVA]

OP writes:

1) while(<stdin>){print " I saw $_" ;} # Is thie (sic) equivalent to 2) while($_=<stdin>){ print "I saw $_" ;} so how will while loop end because undefined value in the $_ will not let the loop end

In Perl, the assignment $_ = <> doesn't necessarily make $_ "defined"? Strange isn't it? But here is how it happens:

 my $x = undef;   #clears out $x and makes it undefined
 my $y = $x;      #since $x is undefined, so is $y

It might be easier to think of "undefined" in Perl as "null" rather than "not yet assigned".

Also, it isn't necessary for $_ to be undefined (or unassigned) for the loop to end. A while loop ends when expr in while (expr) evaluates to false. Being undefined is only one way of being false. Other ways of being false are:

• being equal to 0
• being equal to the empty string, ''

Best, beth

[ikegami]

Also, it isn't necessary for $_ to be undefined (or unassigned) for the loop to end.

While that's true in general,

>perl -le"$_=4; while (--$_) { print }"
3
2
1

It's not true in this case.

>perl -e"print 0" | perl -le"while ($_ = <>) { print $_ ? 'true' : 'fa
+lse' }"
false

>perl -MO=Deparse -e"while (<>) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

>perl -MO=Deparse -e"while ($_ = <>) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

>perl -MO=Deparse -e"while (defined($_ = <>)) {}"
while (defined($_ = <ARGV>)) {
    ();
}
-e syntax OK

[ELISHEVA]

Thanks! Learn something every day! (well, lots today). But what is going on here? What (under the covers) makes this a special case? Why is Perl wrapping $_=<> in defined($_ =<>)? Another convenience feature? And where else does this happen?

Here's my output with a slightly expanded print line checking both the value and the defined status and just to make sure there was no monkey business with the special variable $_ I changed it to $line - same result as you, of course. (I had to switch " and ' to keep the bash shell from trying to resolve $_):

$  perl -e'print 0' | perl -e'while ($line = <>) { print "\$line=<$lin
+e> \$line=<" . ($line ? "true" : "false") . "> defined=<" . (defined(
+$line) ? "true" : "false") . ">\n"};'
$line=<0> $line=<false> defined=<true>

It is also not anything special about the syntax $somevar = <> because I get the same result if I use readline(...):

$ perl -e'print 0' | perl -e'while ($line = readline(*STDIN)) { print 
+"\$line=<$line> \$line=<" . ($line ? "true" : "false") . "> defined=<
+" . (defined($line) ? "true" : "false") . ">\n"};'
$line=<0> $line=<false> defined=<true>

Or is it? Could it be that both while($somevar = readline(...)) and while($somevar = <...>), but only these, have special semantics? I noticed that if I wrap readline in a function of my own that the special behavior goes away. For example,

use strict;
use warnings;

#The following all output:
#  BEFORE
#  $line=<0> $line=<false> defined=<true>
#  AFTER
#
# while (my $line = readline(*STDIN)) {
# while (my $line = <STDIN>) {
# while (my $line = <>) {
#
# but wrapping readline in a sub produces only
# BEFORE
# AFTER

print "BEFORE\n";
while (my $line = wrapped_readline(\*STDIN)) {
 print "\$line=<$line> \$line=<"
   . ($line ? "true" : "false") . "> defined=<"
   . (defined($line) ? "true" : "false") . ">\n";
}
print "AFTER\n";

sub wrapped_readline {
  my $fh = shift @_;
  my $sLine = readline($$fh);
  #print "wrapped_readline: <$sLine>\n";
  return $sLine;
}

Thanks in advance, beth

Update: refined question a bit; fixed error in sub of $_ with $line; added examples using readline and a sub wrapping readline.