Interpretting character combinations as special characters.

[music_man1352000]

Hi all. Here is a tricky little problem for you!

I am writing a script that reads in some textual content in which special characters (newline, tab etc.) have been converted to their string representations. For example, all newline characters in the input have been converted to "\n" (the string literal; literally '\' then 'n'). The input also contains escape sequences such as "\(" and "\)" (parentheses were meta characters in the context where the input content was produced). My script needs to convert the special character sequences back into the original special characters (ie. "\n" needs to be interpretted as the newline character again) and un-escape the meta characters as well. My question is how do I do this?

I have tried a couple of approaches:

my $char = 'n';
$char = sprintf("\\%s", $char);

my $char = 'n';
$char =~ s/(n)/\\$1/;

I would prefer the solution to be general so I don't have to do a regex for each special character (newline, tab etc.) and meta character.

Thanks in advance...

[Corion]

my $string = 'This is\na special\tstring';

my %replace = map { $_ => eval "\\$_" } (qw( n r t ));

$string =~ s/\\(.)/exists $replace{$1} ? $replace{$1} : $1/ge;
print $string;

[afoken]

Three string evals and a map just for lazyness? Why don't you just write my %replace=( n => "\n", t => "\t", r => "\r" );?

Alexander

[Corion]

Exactly for that reason - I'm lazy, as I want to be able to add 0 without much hassle, and possibly other special characters.

[moritz]

my %mapping = (
   '\t'  => "\t",
   '\n'  => "\n",
   '\)'  => ')'.
   '\(   => '(',
);

my $re = join '|', map quotemeta, keys %mapping;

$str =~ s/($re)/$mapping{$1}/g;

This has the advantage of not relying on perl's escaping rules (and thus gives you fine control over what's happening), but has the disadvantage that you have to list all replacements.

[JavaFan]

Listing only those mappings that are different from taking off the leading backslash:

my %mapping = (n => "\n", t => "\t");
$str =~ s{\\(.)}{$mapping{$1}//$1}seg;

This still gives fine control, but you don't have to list everything.

[vitoco]

$text = 'h\te\nll\t\(o\)\n';
print "$text\n";
$text = eval '"'.$text.'"';
print "$text\n";

If not already escaped, you probably have to escape backslashes, double quotes, dollar signs, and some other special chars... Don't know what is worst!

[music_man1352000]

@vitoco: I know what you mean! However your suggestion should actually work perfectly for me because I am reading the input character by character (which means I can do eval's only where I find \'s and not have to escape $, @ % etc.).

@all: thanks once again for all your help!

[afoken]

String eval for arbitary strings? A very optimistic approach. Escaping all those characters that can make perl execute malicious code is surely more work than the other solutions. And if the OP did not understand or ignored the text below your posting, you just made him insert a gapping security hole into his code.

So: --

Alexander

[vitoco]

You are right... I should have begun with a big warning about how evil could eval be.

Fortunately, OP is processing one char at a time, and I couldn't think of a one-byte malicious code. ;-)

BTW, the first solution I though was this:

$text = 'h\te\nl\l\t\(o\)\n';
print "$text\n";
%token = ('\n'=>"\n", '\t'=>"\t" , '\('=>'(', '\)'=>')');
$text =~ s/(\\.)/$token{$1}||$1/ges;
print "$text\n";

That will preserve unknown escape codes from text...

Also, thanks to JavaFan, // operator was new to me...