Regular Expression

[archimca]

Here is the string

%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,bext,excellent
+" grade="7" teacher="Priyanka"}%

with the below mention code I can fetch the value of grade

$var =~ m/%MYBOARD{.*?grade=\"([^\"]*)"[^}]*}%

What would be the regular expression if i want to fetch the value of 'teacher'

[toolic]

use warnings;
use strict;

my $s = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,bext,
+excellent" grade="7" teacher="Priyanka"}%';
if ($s =~ / \b teacher = " ([^"]+) " /x) {
    print "$1\n";
}

__END__

Priyanka

• perlre
• perlretut
• YAPE::Regex::Explain

[Ratazong]

You are thinking very complicated ;-)

Try to find the string teacher, a =", as few chars as possible, and then again a "

$var =~ /teacher="(.*?)"/;

(untested)(update: tested; it works :-)

HTH, Rata

[update2: removed escaping the double quotes (as they are not regex metacharacters) - thanks johngg for the feedback!]

[NetWallah]

Get Both: (Linux run):

>: perl -e 'print qq|$_\n| for q~%MYBOARD{project1|nameofproject1 rema
+rks="Good,Verygood,bext,excellent" grade="7" teacher="Priyanka"}%~=~m
+/grade="([^"]+).+teacher="([^"]+)/'
7
Priyanka

[oko1]

Heck, if you're going to do that, you might as well get it all:

#!/usr/bin/perl -w
use strict;

$_ = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,bext,exc
+ellent" grade="7" teacher="Priyanka"}%';

my %map;
$map{$1} = $2 while s/^.*? (\S+)="([^"]+)"//g;
print "$_: $map{$_}\n" for keys %map;

Output:

grade: 7
teacher: Priyanka
remarks: Good,Verygood,bext,excellent

The above can also be spelled

print map {"$1: $2\n" if /(\S+)="([^"]+)"/} split;

but I suspect that this would be a bit much for the OP... :)

[0xbeef]

Monks are noble creatures and have basic ethical expectations of visitors at the Monastery. So at least try doing *something* before posting here, and at the very least make sure that the code that you post actually works.

Hint 1: The code you claim will fetch a value won't compile.
Hint 2: Try substitution.
Hint 3: Read How do I post a question effectively?

[CountZero]

The following will get your fields and values into a hash in one line:

use Modern::Perl;
use Data::Dumper;

my $text = '%MYBOARD{project1|nameofproject1 remarks="Good,Verygood,be
+xt,excellent" grade="7" teacher="Priyanka"}%';

my %data = $text =~/ ([^=]+)="([^"]+)/g;

say Dumper(\%data);

Output:

$VAR1 = {
          'grade' => '7',
          'teacher' => 'Priyanka',
          'remarks' => 'Good,Verygood,bext,excellent'
        };