Precompiling substitution regex

Greetings,

I'd like to precompile substitution regular expressions in a similar way to precompiling match regexes:

my @MATCH_RE = ( 
  q%(?:this|or|that)%,
);

my @MATCH_REC = map { qr/$_/ } @MATCH_RE;

sub doit {
  my($str) = @_;
  
  for my $re (@MATCH_REC) {
      return 0 if $str =~ m%$re%i;
  }
  return 1;
}
[download]

The above provides the performance gains as expected and works well.

Is it possible to do the same thing for substitution where the replacement string and modifiers can vary, but are hard-coded? For example (incorrect code, I know):

my @SUB_RE = ( 
  q@%(?:this|or|that)%bob%gsi@,    
  q@%(?:One|Two|Three)%Four%gs@,  # note different modifier
);

# or, with 's' embedded
my @SUB_RE2 = ( 
  q@s%(?:this|or|that)%bob%gsi@,    
  q@s%(?:One|Two|Three)%Four%gs@,  # note different modifier
);


my @SUB_REC = map { qr/$_/ } @SUB_RE;

sub doit {
  my($str) = @_;
  
  for my $re (@SUB_REC) {
      $str =~ $re;
  }
  return $str;
}
[download]

Any pointers would be appreciated.

Comment on Precompiling substitution regex Select or Download Code
Re: Precompiling substitution regex by moritz (Cardinal) on Jun 17, 2011 at 11:44 UTC
You can interpolate precompiled regexes into substitutions as well. The different modifiers can go into each regex: `my @SUB_REC = ( qr{(?:this\|or\|that)}si, qr{(?:One\|Two\|Three)}s, ); my @SUBSTITUTION = qw/bob four/; for my $idx (0..$#SUB_REC) { $str =~ s/$SUB_REC[$idx]/$SUBSTITUTION[$idx]/; }` [download] Perl 6 - second systems done right	[reply] [d/l]
Re^2: Precompiling substitution regex by FreakyGreenLeaky (Sexton) on Jun 17, 2011 at 11:57 UTC
Thanks moritz, that will work. Is there any way of achieving that without having the substitutions in a separate array?	[reply]
Re^3: Precompiling substitution regex by moritz (Cardinal) on Jun 17, 2011 at 12:04 UTC
Well, you could of course store an array of closures that each does a substitution, and call those in turn - but it might slow down things again. Or you could store regexes and substitutions in the same array, but distinguished by different indexes (even/odd or first half/second half). But I don't think you can easily store a precompiled whole substitution in a single scalar. Perl 6 - second systems done right	[reply]
Re^4: Precompiling substitution regex by AnomalousMonk (Prior) on Jun 17, 2011 at 18:11 UTC
Re: Precompiling substitution regex by wind (Priest) on Jun 17, 2011 at 22:49 UTC
Use eval to cache the substitution in an anonymous sub: `use strict; use warnings; # Cached Regex's: LHS, RHS, Modifiers my @re_rules = ( ['(?:this\|or\|that)', 'bob', 'gsi'], ['(?:One\|Two\|Three)', 'Four', 'gs'], ); my @re_subs = map { my $sub = eval "sub { s/$_->[0]/$_->[1]/$_->[2] for (\@_)}"; die $@ if $@; $sub; } @re_rules; my @strings = ('this one or that other', 'One two Three'); for my $string (@strings) { $_->($string) for (@re_subs); print "$string\n"; }` [download] Or just declare the anonymous subs yourself if you don't need the special markup: `use strict; use warnings; my @re_subs = ( sub { s/(?:this\|or\|that)/bob/gsi for (@_) }, sub { s/(?:One\|Two\|Three)/Four/gs for (@_) }, ); my @strings = ('this one or that other', 'One two Three'); for my $string (@strings) { $_->($string) for (@re_subs); print "$string\n"; }` [download]	[reply] [d/l] [select]
Re^2: Precompiling substitution regex by FreakyGreenLeaky (Sexton) on Jun 18, 2011 at 09:46 UTC
Thanks. Does the second sample pre-compile the regexes?	[reply]
Re^3: Precompiling substitution regex by wind (Priest) on Jun 18, 2011 at 20:45 UTC
I believe that we're mixing terminology here, as "pre-compile" isn't exactly what you're wanting to ask. Yes, the code is only compiled once and after that point it will not need to be recompiled. I've used this type of mechanism to program configurable filters. Letting a user edit a config file where they specify anonymous subs like that which are later eval'd and used in my larger package.	[reply]


Keep It Simple, Stupid
	PerlMonks

Precompiling substitution regex

The best material for plates (tableware) is: