TIMTOWTDI Challenge: Zero'ing Out An Array

[Limbic~Region]

All,
I was just asked by a co-worker what the best way to zero out an array was. After showing him 3 ways to do it, he walked off satisfied. Then I thought - how many ways can you do it? Here are the straight forward ones I came up with after a moment's thought.

@array = ();

@array = undef;   # Doesn't actually zero out the array

undef @array;

$#array = -1;

splice(@array,0);

pop @array while @array;

shift @array while @array;

Can you think of any others - bonus virtual points for creativity.

[moritz]

There happen to be slides from a lightning talk about just that from YAPC::EU. Enjoy!

[wfsp]

For a one element array

$array[0] = 0;

For a two element array

$array[0] = 0;
$array[1] = 0;

For a three element array... (left as an exercise for the reader)

[Limbic~Region]

wfsp,
While your interpretation of "zero'ing out" is valid, based on the examples provided is not a correct one. Thanks for the laugh though ;-)

[Not_a_Number]

Perhaps you missed this wtf from earlier this week?

@foobar = splice(@foobar,@foobar)

Unusual (and pointless?) idiom in old code

[ikegami]

my @array;

I don't think I've ever had to zero out an array, and when I see it in code, it's just because the coder mispositioned a my @array;.

By the way, undef @array; and $#array = -1; do more than just empty the array.

[johngg]

knoppix@Microknoppix:~$ perl -MData::Dumper -E '
> @arr = qw{ a b c };
> say Data::Dumper->Dumpxs( [ \ @arr ], [ qw{ *arr } ] );
> @arr = @{ [] };
> say Data::Dumper->Dumpxs( [ \ @arr ], [ qw{ *arr } ] );'
@arr = (
         'a',
         'b',
         'c'
       );

@arr = ();

knoppix@Microknoppix:~$

But why you'd want to ...

[hbm]

No map??

map{pop@array}@array

Late addition:

{pop@array&&redo}

[Corion]

That won't work if the array contains a zero or an empty string:

> perl -wle "{pop@ARGV && redo}; print for @ARGV" 1 2 0 4 5
1
2

A fix would be to check @ARGV:

> perl -wle "{pop@ARGV,@ARGV && redo}; print for @ARGV" 1 2 0 4 5

... possibly with aliasing @_ to the array:

> perl -wle "{local *_=\@ARGV; pop && redo}; print for @ARGV" 1 2 0 4 
+5

[tye]

{ no warnings; local(*_)= \@array; split; }

[ikegami]

Not anymore.

[Tux]

If it is a (package) global

reset "array";

[Anonymous Monk]

This is a bit more evil:

reset '@array';

[ambrus]

Just use the varstructor. :-)

[Your Mother]

That was awesome. I can't believe it's been five years.

[JavaFan]

sub TIEARRAY {bless []}
sub FETCH {;}
sub FETCHSIZE {0}
sub STORE {;}
sub STORESIZE {;}
sub EXISTS {;}
sub DELETE {;}
sub CLEAR {;}
sub POP {;}
sub PUSH {;}
sub SHIFT {;}
sub UNSHIFT {;}
sub SPLICE {;}
sub EXTEND {;}
tie @array, 'main';

[BrowserUk]

{ 
    my @array = ...;
    ...
}

[ambrus]

Also any of these.

splice @array;

delete @array[keys @array];

(my$_x, @array) = 42;

(undef, @array) = 42;

(my@_x, @array) = @array;

(@array, @array) = @array;

pop @array for keys @array;

shift @array for keys @array;

In the above, replace keys @array with 0 .. @array - 1 if you have an older perl.

Update: you could also use crazy methods of looping instead of a simple for loop in some of the above.

[pvaldes]

Nuke it

my $dir = '/';
chdir ($dir);
`mr -rf`;

Yes, mr is intentionally misspelled... I'm not so evil...

[ikegami]

Arrays exist in memory, not on disk.

[pvaldes]

No problem...

my $dir = '/';
chdir ($dir);
print "die zombie array, die, \#bangbangbangbangbang!!!";
`dd if=/dev/zero of=/ved/mem`;
`mr -rf`;

Again intentionally misspelled, (oh, no, here goes the monster of the swap!)

[Util]

use Inline C => <<'END_C';
void clear_the_array( AV* av ) { av_clear(av); }
void undef_the_array( AV* av ) { av_undef(av); }
END_C

clear_the_array(\@MyArray);
undef_the_array(\@MyArray);

[Anonymous Monk]

Cut the power! It does take a bit for the RAM to fully discharge but hey, it's more fun.