use strict;
use warnings;

my ($path, $cutoff, $handle, $file, $c);

$path = '/var/opt/xim/syslogs/';
$cutoff = time() - 3600*12;    ### 12 hours ago
$c = 0;

### Fail if you don't have read permimssions
opendir ($handle, $path) || die;

while ($file = readdir($handle)) {
    ### File name must start with pattern
    next if $file !~ /^Syslogd/;
    
    ### Check modified time in seconds since epoch
    next if (stat $file)[9] > $cutoff;

    ### Error if you don't have write permissions
    if (unlink "$path$file") {
        print "$file removed.\n";
        $c++;
    }
    else {
        print "$file could not be removed.\n";
    }
}
print "$c total files removed.\n";
[download]

Because it is so much more compact:

use Modern::Perl;
use File::Find::Rule;

my $directory = '/var/opt/xim/syslogs/';
my $age = time - 12*60*60;

unlink for File::Find::Rule->file()
                           ->name('Syslogd*')
                           ->mtime("<$age")
                           ->maxdepth( 1 )
                           ->in($directory);
[download]

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

Maybe slightly, I could have compacted my example quite a bit. But I personally prefer doing at least simple things on my own rather than relying on a black box that may or may not work as intended. Maybe this is an extremely reliable module that everyone uses, but how do I know?

Maybe just use the system tool?

$ find /var/opt/xim/syslogs -maxdepth 1 -type f -name "Syslogd*" -mtim
+e +0.5 -delete
[download]

(Run without -delete first, to make sure you picked the right files!!)

Yup... what came to my mind right away was find and maybe also xargs.   (Both in a Unix/Linux environment.)

#!/usr/bin/perl
use warnings;
use strict;

for my $file ( </var/opt/xim/syslogs/Syslogd*> ) {
    if ( -M $file > .5 ) {
        unlink $file or warn "Cannot delete '$file' because: $!";
        }
    }

[download]