Either split first and match just the IP part, or remove the $ from the end of your regular expression. The $ matches the end of the line so the total match fails because there is stuff after the IP number.

Although this solution doesn't use split, you can capture the ip between the colon and comma with just a regex--given your file's contents:

use strict;
use warnings;
use 5.010;

say /:(.*),/ while <DATA>;


__DATA__
host1    dns:192.168.243.30,asdf
host2    dns:192.168.243.1,qwert
[download]

I know this doesn't specifically address your "Is there something missing with my code?" question, as the prior comments effectively have, but it may be interesting information to you.

Hope this helps!

Actually the one GodFather helped me by removing the $ sign and just split it if in case i want to display only the ip address. Thanks for the help really appreciate :)

open my $infile, "<", "test.txt" or die "cannot open input: $!";
my @infile1= <$infile>;
close $infile;

foreach my $dns ( @infile1 ) {
    chomp $dns;
    if ($dns =~ /(dns:[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3})$
+/){
    my ($ip, $dns1) = split /dns:/, $dns;
    ($ip) = split /,/, $dns1;
    print "$ip";}
}

[download]

Perhaps you want something like this:

open my $infile, "<", "test.txt" or die "cannot open input: $!";

while ( my $dns = <$infile> ) {
    if ( $dns =~ /dns:([0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3}\.[0-9]{1,3})
+/ ) {
        print "$1";
    }
}
close $infile;

[download]

Regexp::Common (with the automatically loaded Regexp::Common::net) can simplify IP extraction. For one thing, it (Update: can be used to create a regex that) will not match IPs with invalid (Update: decimal) octets such as are allowed by  [0-9]{1,3}   (try different invalid octets in the  $s string).

>perl -wMstrict -le
"use Regexp::Common qw(net);
 ;;
 my $s  = 'host1    dns:192.168.243.30,asdf';
 my $IP = qr{ (?<! \d) $RE{net}{IPv4} (?! \d) }xms;
 my ($ip) = $s =~ m{ $IP }xmsg;
 print qq{ip '$ip'} if $ip;
"
ip '192.168.243.30'
[download]

ofcourse using regex alone you can get your desired output, but since you said you are studying regular expression with splitting, maybe the code below could help:

use warnings;
use strict;

my %hash;
while(<DATA>){
  chomp; 
  my ($dns)=grep $_=>split/^.+?:/,$_;
  my ($ip,$dns1)=split/,/,$dns;
   $hash{$dns1}=$ip;
}
 print $hash{$_},$/ foreach keys %hash;

__DATA__
host1    dns:192.168.243.30,asdf
host2    dns:192.168.243.1,qwert
[download]

You could check perldoc -f split for details
Hope this helps

Here's another regex w/split:

use warnings;
use strict;
use 5.010;

map{say /(.*),/} (split /:/)[1] while <DATA>;

__DATA__
host1    dns:192.168.243.30,asdf
host2    dns:192.168.243.1,qwert
[download]

Actually, by studying split, your are also studying regexes, since split takes a regex.

There are excellent solutions above, including AnomalousMonk's showing how to leverage modules, so you don't need to reinvent the (regex) wheel.

Perl's "There's more than one way to do it" (TMTOWTDI) dictum is clearly evidenced by the many responses to your query, and it can be justifiably asserted about these that--as Adrian Monk says--"It's a blessing, and a curse."