use strict;
use warnings;

my @a = qw(foo bar baz);
my @b = qw(foo bar biz);

foreach my $temp (@a){
    my @matches =  grep {$temp eq $_} @b;
    print "Matches for $temp: ", join(", ", @matches), "\n" if @matche
+s;

}
[download]

• The reason you find that you need to use $temp is that you the $_ associated with the grep is referring to an element of @b, not @a.
• The reason you are getting a count instead of the actual matches is that you are assigning the results to a scalar, not an array.
• One more thing... I believe you are testing for equivalency instead of checking for a pattern match. If you want to perform a typical grep, maybe use something like grep( $temp =~ /$_/, @b )

@a=(11,22,33,44,55);
@b=(22,44,66,17);
foreach (@a) # $_ gets one value from @a
{
  @tested=grep {$_ == $::_} @b; # Had $_ been lexical for grep, $::_ w
+ould've been a global
}
print "\n@tested"; #Doesn't work as expected...$_ and $::_ both are sa
+me and get each value from @b
[download]

I couldn't come up with anything shorter than muba. I tried, but you need at least one temp var (afaict), or else the $_ will confuse iteslf.

my @a = qw( a b c );
my @b = qw( a 3 c );

for my $elem (@a){
    print $elem if grep { $elem eq $_ } @b;
}
[download]

Here another option using smart matching:

use Modern::Perl;

my @a = 1 .. 10;
my @b = 5 .. 14;

say grep $_ ~~ @b, @a;
[download]

Output:

Hope this helps!

Is this Perl version specific?

Smart matching started in Perl 5.10

Thanks all!

Just wanted to be sure I was doing the right thing.

elements from array @a that are not in array @b

The more idiomatic way to do this is with a lookup hash. The combination of for/grep is actually two nested loops, meaning that you do a*b comparisons. A hash lookup will be faster for most situations, and clearer to anyone with much Perl experience. To show elements of @a not in @b:

#!/usr/bin/env perl
use Modern::Perl;

my @a = qw/ foo bar baz /;
my @b = qw/ foo bar biz /;

my %b = map { $_ => 1 } @b;

for (@a){
    say unless $b{$_};
}
[download]

elements from array @a that are not in array @b

Here's another option for that:

use Modern::Perl;
use List::Compare;

my @a = 1 .. 10;
my @b = 5 .. 14;

my $lc = List::Compare->new(\@a, \@b);

say $lc->get_unique;
[download]

Output:

1234
[download]

ps Aaron, I always appreciate your postings...