Thanks for your suggestion. I agree with you that each is special. According to chromatic's explanation, delete belongs to "weak keywords', and each doesn't. By the way, I'm not sure how to add a BEGIN block to my code. Would you please attach your code?

I think choroba’s point is that you can use BEGIN blocks to determine when the warning is issued. For example:

#! perl
use strict;
use warnings;

BEGIN      { print "BEGIN 1\n"; }
sub each   { warn  'main::each() was called' }
BEGIN      { print "BEGIN 2\n"; }
sub delete { warn  'main::delete() was called' }
BEGIN      { print "BEGIN 3\n"; }

my %person = (name => 'Ken Takakura');

while (my ($key, $val) = each %person)
{
    print "$key: $val\n";
}
    
delete $person{name};

BEGIN      { print "BEGIN 4\n"; }
[download]

produces this output:

BEGIN 1
BEGIN 2
BEGIN 3
Ambiguous call resolved as CORE::each(), qualify as such or use & at 1
+66_SoPW.pl line 13.
BEGIN 4
name: Ken Takakura
[download]

which shows that the warning is issued during the compile phase (before the main code is executed) at the point where the code specifies an ambiguous call to each.

This works because BEGIN blocks are executed during compilation, as soon as they are seen by the Perl compiler, before the main code is run. See BEGIN, UNITCHECK, CHECK, INIT and END.

HTH,

Athanasius <°(((>< contra mundum

Perl's tokenizer classifies some keywords as "weak keywords" such that you can override them with user-defined functions. (Calling them is another matter.) delete is a weak keyword and each is not. our is weak, but sub is not:

use strict;
use warnings;

sub each   { warn 'main::each() was called' }
sub delete { warn 'main::delete() was called' }
sub dump   { warn 'main::dump() was called' }
sub chop   { warn 'main::chop() was called' }
sub our    { warn 'main::our() was called' }

my %person = ( name => 'Ken Takakura' );

while ( my ($key, $val) = each %person ) {
    print "$key: $val\n";
}

&our( $person{name} );
delete $person{name};
chop $person{name};
dump( $person{name} );
[download]

I don't know how to make a list of weak and normal keywords without reading the source code (keywords.c or regen/keywords.pl).

Thanks for your suggestion. Your code output the following:

Ambiguous call resolved as CORE::each(), qualify as such or use & at a
+mbiguous_calls.pl line 12.
Ambiguous call resolved as CORE::chop(), qualify as such or use & at a
+mbiguous_calls.pl line 18.
dump() better written as CORE::dump() at ambiguous_calls.pl line 19.
Ambiguous call resolved as CORE::dump(), qualify as such or use & at a
+mbiguous_calls.pl line 19.
name: Ken Takakura
main::our() was called at ambiguous_calls.pl line 8.
Use of uninitialized value $person{"name"} in scalar chop at ambiguous
+_calls.pl line 18.
Abort
[download]

This result shows us that delete and our belong to "weak keywords", and each, chop and dump don't.

The following was quoted from regen/keywords.pl:

145: -chop
160: +delete
163: -dump
164: -each
261: +our
[download]

Plus (+) signs maybe mean "weak".

Your comment meant a lot to me :)