Re^2: Perl Elitist Code vs Functional Code

[tobyink]

in reply to Re: Perl Elitist Code vs Functional Code
in thread Perl Elitist Code vs Functional Code

Don't constantly retype boilerplate code. Wrap it in reusable functions. Here's an example for your status/error messages...

package MyProject::Sugar::Catalyst;

use Sub::Exporter -setup => {
    exports => [
        error_msg => \&_build_error_message,
    ],
    groups => {
        default   => [qw/ error_msg /],
    },
};

sub _build_error_message
{
    my ($class, $name, $def) = @_;
    return sub
    {
        my ($c, %arg) = @_;
    
        my $uri = $arg{uri}
            || $def->{uri}
            or die "No URI supplied";
        my $msg = $arg{msg}
            || $def->{msg}
            || 'Oh noes, ANOTHER FUCKING ERROR!!!';
        
        $c->res->redirect(
            $c->uri_for($uri, { mid => $c->set_error_msg($msg) })
        );
        $c->detach();
    }
}

An example of usage:

package MyProject::Controller::Foobar;

use MyProject::Sugar::Catalyst
  db_error_msg   => { msg => "Database Error!" },
  http_error_msg => { msg => "HTTP Error!" },
  error_msg      => { };

...;

sub foo_bar
{
    ...;
    db_error_msg($c, uri => $uri);
}

sub foo_baz
{
    ...;
    db_error_msg($c, uri => $uri, msg => "specific error message");
}

It makes things easier in the long run.

[Anonymous Monk]

closures really?

I'd rather use die/croak and a something like Catalyst::Plugin::ErrorCatcher

[tobyink]

Yes, closures are how Sub::Exporter works. Moose uses Sub::Exporter under the hood to export its has, extends, etc keywords. has, extends, etc are all closures. Catalyst is Moose-based. You use Catalyst; you're using closures.

Catalyst is Plack-based. Plack is an implementation of the PSGI spec. Under PSGI all web apps are closures. You use Catalyst; you're using closures.