Passing variables into a subroutine

[Freezer]

There appears not to be a logical reason why the following should not work:

sub create_output (@) {
    
    my (@array_of_lines, $entry_no_new) = @_;    # THIS DOES NOT WORK

However it doesn't. What is the solution please?

[CountZero]

Your prototype definition is wrong. Your definition of (@) says that your sub takes one array or list as argument, so all arguments are flattened into one list. This is the way any "normal" subroutine without prototypes works.

However now consider this:

use Modern::Perl;

sub create_output (\@$) {
    my ($arrayref_of_lines, $entry_no_new) = @_;
    say "array:  @{$arrayref_of_lines}";
    say "scalar: $entry_no_new";
}
my @array = qw/1 2 3 4/;
create_output @array, 5;

And its output:

array:  1 2 3 4
scalar: 5

This is actually one of the few cases of a prototype being applied in a useful way.

The prototype (\@$) means the first argument to your sub MUST start with a @ (in other words, it must be an array), followed by a scalar. Due to the (\@) in the prototype, Perl actually takes a reference to the array and passes that as the first argument to your sub. So don't you forget to de-reference it in your sub!

It is this automagical referencing that allows you to pass one or more arrays to a subroutine without them all getting flattened in one big @_.

[Freezer]

Perl actually takes a reference to the array and passes that as the first argument to your sub. So don't you forget to de-reference it in your sub!



Is there a popper way to do the dereferencing, given the context?

[CountZero]

Sadly, there will be no automatic dereferencing done by Perl. But it is very easy to do: to get the original array, just add the @ sigil to the front of the scalar holding the reference.

[Freezer]

Is something like the following equally cool?

sub look_through_file ($$) {   
    
    my ($start_point, $continue_tag) = @_;

[CountZero]

As a general rule don't use prototypes unless there is a good reason for it such as passing in several arrays without them getting flattened into one @_. And even then passing references to the arrays is probably a more clear solution.

I see no merit in adding a prototype definition of ($$).

[choroba]

The problem is in the assignment. You can never make this work:

my (@array, ...) = ...

because the array takes all the values.

Update: Other problems may emerge after solving this one because of the usage of prototypes.

[daxim]

I guess you want

sub create_output {                    # no prototype
    my ($lines, $entry_no_new) = @_;   # $lines is arrayref

See The purpose of prototypes in perl subroutines, The Problem with Prototypes, Why are Perl 5's function prototypes bad?, Prototype

[Corion]

You don't tell us how it fails for you (besides the obvious syntax error).

Perl flattens passed parameters into @_. perlsub explains some more of that.

[AnomalousMonk]

The other alternative, if you don't want to deal with references and if there is only one array (or hash) to be passed, is to pass any and all scalars (and there can be more than one) first, and then pass the sole array (or hash). The following works the same way with or without the  (@) prototype for the reason explained by CountZero (i.e., in general, don't bother with prototypes):

perl -wMstrict -le
"sub S {
   my ($scalar, @ra) = @_;
   ;;
   print qq{scalar: '$scalar'  array:(@ra)};
   }
 ;;
 my @array = (1, 2, 3);
 S('foo', @array);
"
scalar: 'foo'  array:(1 2 3)

[evaluator]

Try this (untested):

my $entry_no_new   = pop @_;
my @array_of_lines = @_;

or

my @array_of_lines = @_;
my $entry_no_new   = pop @array_of_lines;