#!/usr/bin/perl
#
use strict;
use warnings;

$ARGV[0] or die "Usage: $0 <filename> [<filename>] ...";

my ( $template_file_name, $templateText, %hash ) = '';

for my $csvFile (@ARGV) {
	print "\nProcesing file $csvFile ...\n";
	open my $csvfh, '<', $csvFile or die "Unable to open $csvFile: $!";

	# Ignore column names in first line
	my $columnNames = <$csvfh>;

	# Get vars from second line
	chomp( my $vars = <$csvfh> );
	my @vars = split /,/, $vars;

	while (<$csvfh>) {
		chomp;
		my @fields     = split /,/;
		my $templateFN = pop @fields;

		if ( $template_file_name ne $templateFN ) {
			$template_file_name = $templateFN;
			undef $templateText;
		}

		@hash{@vars} = @fields;

		$templateText //= getTemplateText($template_file_name);
		my $templateTextCopy = $templateText;

		$templateTextCopy =~ s/$_/$hash{$_}/g for keys %hash;

		my $ofile_name = $hash{'##rtrname##'} . '.txt';

		print "Writing to file: $ofile_name\n";
		open my $fh, '>', $ofile_name or die "$ofile_name: $!";
		print $fh $templateTextCopy;
		close $fh;
	}

	close $csvfh;
}

print "\nDone!\n";

sub getTemplateText {
	my ($template_file_name) = @_;

	local $/;
	open my $fh, '<', $template_file_name or die "$template_file_name: $!";
	$templateText = <$fh>;
	close $fh;

	return $templateText;
}