I'm trying to (ab)use hash slices. I understand the typical (@hash{@keys}) use of a slice, but now I'm trying to do something a bit more complex and take a slice of a hash of hashes. Using a slice in a %HoH when the list is provided as the second 'key' is no problem, but can slices be used to cut across the first set of keys as well? I didn't find anything when I searched for this in the docs or on PM.

Perhaps a bit of code will help define the problem:

use strict;
use warnings;

my @keys = qw( a c );

my %hash = ( a => 1, b => 2, c => 3, d => 4 );

# typical use - no problem
# @hash{a,c} is like $hash{a}, $hash{c}
print join( ' ', @hash{@keys} ), "\n"; # 1, 3

my %hoh = ( a => { a => 'a1', b => 'a2', c => 'a3', d => 'a4' },
            b => { a => 'b1', b => 'b2', c => 'b3', d => 'b4' },
            c => { a => 'c1', b => 'c2', c => 'c3', d => 'c4' },
            d => { a => 'd1', b => 'd2', c => 'd3', d => 'd4' } );

# typical use expanded to a %HoH - no problem
# @{ $hoh{b} }{a, c} is like $hoh{b}{a}, $hoh{b}{c}
print join( ' ', @{ $hoh{b} }{@keys} ), "\n"; # b1, b3

# now I want to slice across the first key instead of the second
# want something like $hoh{a}{d}, $hoh{c}{d}
print join( ' ', @hoh{@keys}{d} ), "\n"; # syntax error

# I tried dereferencing the list of hashrefs, but only
# the last ref in the list was used ($hoh{c})
print join( ' ', @{ @hoh{@keys} }{d} ), "\n"; # c4

# do I have to resort to this?
print join( ' ', map{ $_->{d} } @hoh{@keys} ), "\n"; # a4 c4
[download]

As illustrated in the code above, I used map to get it to work but if there is a way to use a slice I'd like to learn how to do it.

Aside: If this is possible, though, it immediately implies one could slice across both directions at once:

# yikes!!
print join( ' ', @hoh{@keys}{@keys} ), "\n"; # a1 a3 c1 c3 ??
[download]

Thanks!

Update: clarified the main question