I find that the following 4 simple rules cover all of the ways to dereference data structure references. Having the rules spelled out so simply has made using references much less confusing to me.

1. To use a reference, say $ref, you put {$ref} in place of a variable name ( not counting the $, %, or @ ). That is, replace the variable name with the reference enclosed in braces:

       $scalar        ${$sRef}
       @array         @{$aRef}
       $array[0]      ${$aRef}[0]
       $#array        $#{$aRef}
       %hash          %{$hRef}
       $hash{KEY}     ${$hRef}{KEY}
       @hash{@list}   @{$hRef}{@list}
   [download]

   Note that this works for any expression that returns a reference, not just the simple examples above:

       ${$sRefs[0]}   ${$sRefs{key}}   ${getScalarRef()}
       @{$aRefs[0]}   @{$aRefs{key}}   @{getArrayRef()}
       %{$hRefs[0]}   %{$hRefs{key}}   %{getHashRef()}
       @{ $bool ? \%hash1 : \%hash2 }{qw(some keys)}
   [download]

2. If the reference is held in a simple scalar variable, then the braces, { and }, can be dropped:

       $scalar        $$sRef
       @array         @$aRef
       $array[0]      $$aRef[0]
       $#array        $#$aRef
       %hash          %$hRef
       $hash{KEY}     $$hRef{KEY}
       @hash{@list}   @$hRef{@list}
   [download]

3. If you are getting a scalar from a hash or an array, then you can replace ${$ref} with $ref->:

       $array[0]     ${$aRef}[0]     $aRef->[0]
       $hash{KEY}    ${$hRef}{KEY}   $hRef->{KEY}
   [download]

4. If the reference is in a hash or an array (and you are getting back a scalar), then you can drop the -> between the adjacent [0] and/or {KEY} parts:

       ${$aRef->[0]}[1]    $aRef->[0]->[1]    $aRef->[0][1]
       ${$aRef->[0]}{KEY}  $aRef->[0]->{KEY}  $aRef->[0]{KEY}
       ${$hRef->{KEY}}[1]  $hRef->{KEY}->[1]  $hRef->{KEY}[1]
       ${$hRef->{A}}{B}    $hRef->{A}->{B}    $hRef->{A}{B}
   [download]

I hope others find this as helpful as I have.

Thanks to arturo for suggesting that I turn references quick reference (Re: push) into a tutorial.

Thanks to kutsu for pointing out that I've had ${hRef}{KEY} instead of ${$hRef}{KEY} for all these years.