You need to set up the top level structure of your output document outside of the while loop.

Also, even if this is nothing which fails your code at the moment, you should also concider using a hash instead of evaling symbolic variable names.

use strict;
use warnings;
use XML::Writer;
#use XML::Reader;
use IO::File;

open(my $fh,"./input.txt") or die "Cannot open input file.";
my $output = new IO::File(">converted_to_xml.xml"); #file to write the
+ converted content
my $writer = new XML::Writer(OUTPUT => $output); #write into the opene
+d file

my @array=qw(name emp_no designation salary);

$writer->xmlDecl("UTF-8"); #XML declaration
$writer->startTag("data"); # The root tag
while(my $input=<$fh>){
    chomp($input);
    next if !$input;
    my %vals;
    @vals{@array} = split /:/, $input;
    $writer->startTag("row"); # enclosing tag for every data row
    for my $name (@array) {
        $writer->startTag($name);
        $writer->characters($vals{$name});
        $writer->endTag();
    }
    $writer->endTag(); # = endTag("row")
}
$writer->endTag(); # = endTag("data")
$writer->end();
$output->close();
[download]

Update: Typically you want some structure in the XML document, to address whole data rows. Added the "row" tag level for that.