$ cat groupify_a.pl
#!/usr/bin/perl         
use strict;
use warnings;

my %Grps;

# Build the groups
while (<DATA>) {
    my ($l,$r) = split /\s*,?\s+/, $_;
    last unless defined $r;

    my $gl = $Grps{$l};
    my $gr = $Grps{$r};

    if (defined $gl) {
        if (defined $gr) {
            if ($gr != $gl) {
                # Merge two groups
                my %new_gr = map { $_=>0 } @$gr, @$gl;
                my $new_gr =  [ sort keys %new_gr ];
                $Grps{$_} = $new_gr for @$new_gr;
            }
        }
        else {
            # Add $r existing group
            push @{$Grps{$r}=$gl},$r;
        }
    }
    elsif (defined $gr) {
        # Add $l to existing group
        push @{$Grps{$l}=$gr},$l;
    }
    else {
        # Create new group
        my $new_gr = [ $l, $r ];
        $Grps{$_} = $new_gr for @$new_gr;
    }
}

#...and print them
for my $K (keys %Grps) {
    next unless @{$Grps{$K}}>0;
    print "{ ", join(", ", splice @{$Grps{$K}}), " }\n";
}
__DATA__   
A, B       
C, D       
A, C       
E, F       
F, G       

$ perl groupify_a.pl
{ E, F, G }
{ A, B, C, D }