#!/usr/bin/perl --
use strict;
use warnings;
use XML::LibXML 1.70; ## for load_html/load_xml/location
use Data::Dump qw/ dd pp /;
Main( @ARGV );
exit( 0 );
sub Main {
    my $loc = shift or die "
Usage:
    $0  ko00010.xml
    $0  http://example.com/ko00010.xml\n\n";

    my $dom = XML::LibXML->new(
        qw/ recover 2 /
    )->load_xml(
        location => $loc,
    );

    orWhat( $dom -> documentElement );
}

sub orWhat {
    my( $parent, $depth ) = @_;
    $depth ||= 0;
    my $dent = ' ' . ' ' x $depth;
    
    for my $child ( $parent->getAttributes ){
        printf "%s%s[%s]\n", $dent, $child ->getName, $child->getValue;
    }
    
    for my $kid ( $parent->nonBlankChildNodes ){
        printf "%s%s[%s]\n", $dent, $kid->getName, pp( $kid->getValue );
        orWhat( $kid, $depth + 1 ); ## recurse
    }
    return;
}
__END__
 name[path:ko00010]
 org[ko]
 number[00010]
 title[Glycolysis / Gluconeogenesis]
 image[http...]
 link[http...]
 entry[undef]
  id[13]
  name[ko:K01623 ko:K01624 ko:K01622 ko:K16306]
  link[http...]
  graphics[undef]
   name[K01623...]
   fgcolor[#000000]
   bgcolor[#BFBFFF]
   type[rectangle]
   x[483]
   y[404]
   width[46]
   height[17]