Re: Concatenate or Join?

[johngg]

Reducing the join and concatenation to a simple example without any file i/o, I don't get the same result when Benchmarking.

use strict;
use warnings;

use Benchmark qw{ cmpthese };

my @arr = ( q{abc} ) x 10000;

cmpthese( -5, {
   concat => sub { my $ret; $ret .= $_ for @arr; return $ret; },
   join   => sub { my $ret = join q{}, @arr; return $ret; },
   } );

$ ./spw1003500
         Rate concat   join
concat  994/s     --   -70%
join   3310/s   233%     --
$

Perhaps something else is skewing your timing.

[tobyink]

It depends what you're doing really. In your example, join beats concat, but that's because you are looping through an array. Here though, concatenation beats it (albeit only by about 10%):

use strict;
use warnings;
use Benchmark qw{ cmpthese };

sub foo { 'abc' };
sub bar { 'def' };

cmpthese( -3, {
    concat => sub { my $ret = foo().bar(); return $ret; },
    join   => sub { my $ret = join q{}, foo(), bar(); return $ret; },
});

And here (thanks to the Perl compiler being so good at constant folding) concatenation is more than twice as fast as join:

use strict;
use warnings;
use Benchmark qw{ cmpthese };

sub foo () { 'abc' };
sub bar () { 'def' };

cmpthese( -3, {
    concat => sub { my $ret = foo . bar; return $ret; },
    join   => sub { my $ret = join q{}, foo, bar; return $ret; },
});