#!/usr/bin/perl

use OpenGL ':all';
use strict;
use warnings;

my $checker;

main();


sub init {
  glClearColor(0,0,0,0);
  glShadeModel(GL_FLAT);
  glEnable(GL_DEPTH_TEST);

  my $bm;
  glPixelStorei(GL_UNPACK_ALIGNMENT, 1);
  glGenTextures_s(1, $checker);
  $checker = unpack "I", $checker;
  for my $i (0 .. 63) {
    for my $j (0 .. 63) {
      my $c = ((($i & 8) == 0) ^ (($j & 8) != 0)) * 255;
      $bm .= pack "C4", $c, $c, 0, 255;
    }
  }

  glBindTexture(GL_TEXTURE_2D, $checker);

  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST);
  glTexParameteri(GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST);

  glTexImage2D_s(
    GL_TEXTURE_2D, 0, GL_RGBA,
    64, 64,
    0, GL_RGBA, GL_UNSIGNED_BYTE, $bm,
  );
}


sub display {
  glClear(GL_COLOR_BUFFER_BIT | GL_DEPTH_BUFFER_BIT);
  glEnable(GL_TEXTURE_2D);
  glTexEnvf(GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_DECAL);
  glBindTexture(GL_TEXTURE_2D, $checker);

  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity();
  glTranslatef(0.0, 0.0, -2.0);

  glBegin(GL_QUADS);
  glTexCoord2f(0.0, 0.0); glVertex3f(-1.0, -1.0, 1.0);
  glTexCoord2f(0.0, 1.0); glVertex3f(-1.0, 1.0, 1.0);
  glTexCoord2f(1.0, 1.0); glVertex3f(1.0, 1.0, 1.0);
  glTexCoord2f(1.0, 0.0); glVertex3f(1.0, -1.0, 1.0);
  glEnd();

  glFlush();
  glDisable(GL_TEXTURE_2D);
  glutSwapBuffers();
}


sub reshape {
  my ($w, $h) = @_;
  glViewport(0, 0, $w, $h);
  glMatrixMode(GL_PROJECTION);
  glLoadIdentity();
  gluPerspective(112.5, $w/$h, 0.01, 30.0);
  glMatrixMode(GL_MODELVIEW);
  glLoadIdentity();
  glTranslatef(0.0, 0.0, -3.0);
}


sub keyboard {
  my ($key, $x, $y) = @_;
  if ($key == 27) { exit }
}


sub main {
  glutInit();
  glutInitDisplayMode(GLUT_SINGLE | GLUT_RGB | GLUT_DEPTH);
  glutInitWindowSize(250, 250);
  glutInitWindowPosition(100, 100);
  glutCreateWindow($0);
  init();
  glutDisplayFunc(\&display);
  glutReshapeFunc(\&reshape);
  glutKeyboardFunc(\&keyboard);
  glutMainLoop();
  return 0; 
}