use strict;
use warnings;
use 5.010;

package My::Base;
use Moose;

has 'attr' => (is => 'rw', isa => 'Str', required => 1);

around 'attr' => sub {
  my $orig = shift;
  my $self = shift;
  
  my $response = $self->$orig(@_);
  return "The value of attr is '$response'"
};

package My::Derived;
use Moose;

extends 'My::Base';

has '+attr' => (required => 0, lazy_build => 1);

sub _build_attr {
  return "default value";
}

package My::Inherited;
use Moose;

extends 'My::Base';

package main;
use Test::More tests => 9;
use Test::Exception;

throws_ok {My::Base->new()} qr/Attribute \(attr\) is required/, q/base requires 'attr' at construction/;
my $base = new_ok('My::Base' => [attr => 'constructor value']);
cmp_ok($base->attr, 'eq', "The value of attr is 'constructor value'", 'base is correct');
lives_ok {My::Derived->new()} q/derived doesn't require 'attr' at construction/;
my $der = new_ok('My::Derived');
cmp_ok($der->attr, 'eq', "The value of attr is 'default value'", 'derived is correct');
throws_ok {My::Base->new()} qr/Attribute \(attr\) is required/, q/inherited requires 'attr' at construction/;
my $inh = new_ok('My::Inherited' => [attr => 'constructor value']);
cmp_ok($inh->attr, 'eq', "The value of attr is 'constructor value'", 'inherited is correct');